UDefinitions.pas

unit UDefinitions;

interface

uses System.Generics.Collections, System.Classes, system.IOUtils;

const DEFINITIONS_VERSION = 3; //current definitions template

type
  TPackage = class
  public
    Name: string;
    Path: string;
    Allow64bit: Boolean;
    PublishFiles: TStringList;
    Install: Boolean;
    FOptRegisterName : string;
    FOptBuildConfig : string;
    constructor Create;
    destructor Destroy; override;
  end;
  TPackages = class(TObjectList<TPackage>);

  TDefinitions = class
  public
    IniVersion: Integer;
    CompName: string;
    CompVersion: string;
    DelphiVersions: string;
    AddLibrary: Boolean;
    OutputPath: string;
    Packages: TPackages;
    GitHubRepository: string;
    AutoUpdateIniFile : boolean;
    UpdatedVersion : string;
    procedure LoadIniFile(const aFile: string);
    procedure ReloadPackages(const aFile, aDelphiVersion : string);


    function HasAny64bit: Boolean;

    constructor Create;
    destructor Destroy; override;
  end;

implementation

uses System.IniFiles, System.SysUtils, uCommon;

function PVToEnter(const A: string): string;
begin
  //replaces all ";" to ENTER definition
  Result := StringReplace(A, ';', #13#10, [rfReplaceAll]);
end;

procedure TDefinitions.LoadIniFile(const aFile: string);
var
  Ini: TIniFile;
  A, Sec: string;
  S: TStringList;
  P: TPackage;
begin
  if not FileExists(aFile) then
    raise Exception.Create('Ini file not found');

  Ini := TIniFile.Create(aFile);
  try
    IniVersion := Ini.ReadInteger('Template', 'IniVersion', 1);
    if IniVersion>DEFINITIONS_VERSION then
      raise Exception.Create('Unsupported ini version. You probably need to update Component Installer!');

    CompName := Ini.ReadString('General', 'Name', '');
    if CompName='' then
      raise Exception.Create('Component name not specifyed at ini file');

    CompVersion := Ini.ReadString('General', 'Version', '');
    if CompVersion='' then
      raise Exception.Create('Component version not specifyed at ini file');

    DelphiVersions := Ini.ReadString('General', 'DelphiVersions', ''); //splitted by ";"
    if DelphiVersions='' then
      raise Exception.Create('No Delphi version specifyed at ini file');

    AddLibrary := Ini.ReadBool('General', 'AddLibrary', False);
    OutputPath := Ini.ReadString('General', 'OutputPath', '');
    AutoUpdateIniFile := Ini.ReadInteger('General', 'AutoUpdateIniFile', 0) <> 0;

    S := TStringList.Create;
    try
      S.Text := PVToEnter( Ini.ReadString('General', 'Packages', '') );
      if S.Count=0 then
        raise Exception.Create('No package found in the ini file');

      for A in S do
      begin
        P := TPackage.Create;
        Packages.Add(P);

        Sec := 'P_'+A;

        P.Name := A;
        P.Path := Ini.ReadString(Sec, 'Path', '');
        P.Allow64bit := Ini.ReadBool(Sec, 'Allow64bit', False);
        P.PublishFiles.Text := PVToEnter( Ini.ReadString(Sec, 'PublishFiles', '') );
        P.Install := Ini.ReadBool(Sec, 'Install', False);
        p.FOptBuildConfig := ini.ReadString(Sec,'BuildConfig', 'Release');
        p.FOptRegisterName := ini.ReadString(Sec,'RegisterName', '');
      end;

    finally
      S.Free;
    end;

    GitHubRepository := Ini.ReadString('GitHub', 'Repository', '');

  finally
    Ini.Free;
  end;
end;

procedure TDefinitions.ReloadPackages(const aFile, aDelphiVersion: string);
var
  Ini: TIniFile;
  A, Sec,
  LVerSec: string;
  S: TStringList;
  P: TPackage;
  LIter : integer;
begin
  if not FileExists(aFile) then
    raise Exception.Create('Ini file not found');

  //Reset Packages
  if Assigned(Packages) then
  begin
    Packages.Clear;
    Packages.free;
  end;
  self.Packages := TPackages.Create;

  Ini := TIniFile.Create(aFile);
  try
    S := TStringList.Create;
    try
      S.Text := PVToEnter( Ini.ReadString('General', 'Packages', '') );
      if S.Count=0 then
        raise Exception.Create('No package found in the ini file');

      for A in S do
      begin
        P := TPackage.Create;
        Packages.Add(P);

        Sec := 'P_'+A;
        LVerSec := 'P_'+A+'_'+aDelphiVersion;

        if ini.SectionExists(LVersec) then
        begin
          Sec := LVersec;
        end;
        P.Name := A;
        P.Path := Ini.ReadString(Sec, 'Path', '');
        P.Allow64bit := Ini.ReadBool(Sec, 'Allow64bit', False);
        P.PublishFiles.Text := PVToEnter( Ini.ReadString(Sec, 'PublishFiles', '') );
        P.Install := Ini.ReadBool(Sec, 'Install', False);
        p.FOptBuildConfig := ini.ReadString(Sec,'BuildConfig', 'Release');
        p.FOptRegisterName := ini.ReadString(Sec,'RegisterName', '');
      end;

    finally
      S.Free;
    end;

    GitHubRepository := Ini.ReadString('GitHub', 'Repository', '');

  finally
    Ini.Free;
  end;
end;

{ TDefinitions }

constructor TDefinitions.Create;
begin
  inherited;
  UpdatedVersion := '';
  Packages := TPackages.Create;
end;

destructor TDefinitions.Destroy;
var
  ini : Tinifile;
begin
  if AutoUpdateIniFile and (UpdatedVersion <> '') then
  begin
    if (CompVersion <> UpdatedVersion) then
    begin
      ini := Tinifile.Create(tpath.combine(TPath.GetAppPath, INI_FILE_NAME));
      try
        ini.WriteString('General', 'Version', UpdatedVersion);
      finally
        ini.free;
      end;
    end;
  end;
  Packages.Free;
  inherited;
end;

function TDefinitions.HasAny64bit: Boolean;
var
  P: TPackage;
begin
  Result := False;

  for P in Packages do
    if P.Allow64bit then
    begin
      Result := True;
      Break;
    end;
end;

{ TPackage }

constructor TPackage.Create;
begin
  inherited;
  PublishFiles := TStringList.Create;
end;

destructor TPackage.Destroy;
begin
  PublishFiles.Free;
  inherited;
end;

end.