CommandScheduler/build.gradle.kts at master · CloudCraftProjects/CommandScheduler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
plugins {
    id("java-library")
    id("maven-publish")

    id("net.minecrell.plugin-yml.bukkit") version "0.6.0"
    id("xyz.jpenilla.run-paper") version "3.0.2"
    id("com.gradleup.shadow") version "8.3.9"
}

group = "dev.booky"
version = "1.0.0-SNAPSHOT"

val plugin: Configuration by configurations.creating {
    isTransitive = false
}

repositories {
    maven("https://repo.cloudcraftmc.de/public/")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")

    val cloudcore = "1.1.0-SNAPSHOT"
    compileOnlyApi("dev.booky:cloudcore:$cloudcore")
    val commandapi = "11.0.0"
    compileOnly("dev.jorel:commandapi-paper-core:$commandapi")

    // testserver dependency plugins (maven)
    plugin("dev.booky:cloudcore:$cloudcore:all")
    plugin("dev.jorel:commandapi-paper-plugin:$commandapi")
}

java {
    withSourcesJar()
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
        vendor = JvmVendorSpec.ADOPTIUM
    }
}

publishing {
    publications.create<MavenPublication>("maven") {
        artifactId = project.name.lowercase()
        from(components["java"])
    }
}

bukkit {
    main = "$group.cmdscheduler.CmdSchedulerMain"
    apiVersion = "1.21.9"
    authors = listOf("booky10")
    depend = listOf("CommandAPI", "CloudCore")
}

tasks {
    runServer {
        minecraftVersion("1.21.10")
        pluginJars.from(plugin.resolve())
    }

    withType<Jar> {
        // no spigot mappings are used, disable useless remapping step
        manifest.attributes("paperweight-mappings-namespace" to "mojang")
    }
}