build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'net.ltgt.errorprone'            version '5.1.0' apply false
    id 'org.asciidoctor.jvm.convert'    version '4.0.5'
    id 'org.ajoberstar.git-publish'     version '4.2.2'
    id 'com.github.hierynomus.license'  version '0.16.1' apply false
}

gradle.rootProject {
    apply plugin: 'distribution'
}

develocity {
    buildScan {
        publishing.onlyIf { System.getenv("CI") != null }
        termsOfUseUrl = 'https://gradle.com/terms-of-service'
        termsOfUseAgree = 'yes'
    }
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'groovy'
    apply plugin: 'test-report-aggregation'
    //apply plugin: 'findbugs'

    version = consensusjVersion     // set in gradle.properties
    group = 'com.msgilligan'

    repositories {
        mavenCentral()
    }

//    tasks.withType(FindBugs) {
//        reports {
//            xml.enabled false
//            html.enabled true
//        }
//    }
}

subprojects {

    dependencies {
        implementation "org.slf4j:slf4j-api:${slf4jVersion}"

        annotationProcessor "com.uber.nullaway:nullaway:${nullAwayVersion}"
    }

    configurations.configureEach {
        resolutionStrategy {
            force "org.apache.groovy:groovy:${groovyVersion}"
            force "org.apache.groovy:groovy-json:${groovyVersion}"
        }
        // Ensure usage of Groovy 4.0 which has new Maven co-ordinates
        resolutionStrategy.capabilitiesResolution.all {
            if (capability.group.equals("org.codehaus.groovy")) {
                selectHighestVersion()
            }
        }
    }

    java {
        withJavadocJar()
        withSourcesJar()
    }

    compileJava {
        options.compilerArgs << '-Xlint:deprecation' << '-Xlint:unchecked'
        if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_21)) {
            options.compilerArgs += ["-XDaddTypeAnnotationsToSymbol=true"]
        }
        options.encoding = 'UTF-8'
        options.release = 11
    }

    tasks.withType(GroovyCompile).configureEach {
        options.encoding = 'UTF-8'
    }

    tasks.withType(AbstractArchiveTask).configureEach {
        // This should result in reproducible JAR builds
        // See: https://docs.gradle.org/current/userguide/working_with_files.html#sec:reproducible_archives
        preserveFileTimestamps = false
        reproducibleFileOrder = true
    }

    tasks.withType(Jar).configureEach {
        // Normalize permissions for reproducible builds
        dirPermissions {
            unix("0755")
        }
        filePermissions {
            unix("0644")
        }
    }

    tasks.withType(Javadoc).configureEach {
        // Support reproducible JavaDoc builds
        options.noTimestamp = true
    }

    // To support nativeTest, we are migrating away from having all subprojects use Spock by default
    def spockLess = ["consensusj-jrpc", "consensusj-jrpc-echod"]
    boolean useSpock = !spockLess.contains(it.name)

    testing {
        suites {
            configureEach {
                useJUnitJupiter()
                dependencies {
                    implementation platform("org.junit:junit-bom:${junitJupiterVersion}")

                    implementation "org.junit.jupiter:junit-jupiter-api:${junitJupiterVersion}"
                    runtimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitJupiterVersion}"

                    runtimeOnly "org.slf4j:slf4j-jdk14:${slf4jVersion}"

                    annotationProcessor "com.uber.nullaway:nullaway:${nullAwayVersion}"

                    if (useSpock) {
                        implementation "org.apache.groovy:groovy:${groovyVersion}"
                        implementation("org.spockframework:spock-core:${spockVersion}") {
                            exclude module: "groovy-all"
                        }

                        runtimeOnly "net.bytebuddy:byte-buddy:1.18.8"   // Lets Spock mock classes (in addition to interfaces)
                        runtimeOnly "org.objenesis:objenesis:3.4"       // Lets Spock mock classes with constructor arguments
                    }
                }
            }
        }
    }
}

apply from: 'gradle/idea.gradle'
apply from: 'gradle/javadoc.gradle'
apply from: 'gradle/asciidoctor.gradle'
apply from: 'gradle/github-pages.gradle'
apply from: 'gradle/maven-publish.gradle'
apply from: 'gradle/licenseCheck.gradle'

dependencies {
    testReportAggregation project(':').subprojects
}

tasks.named('check') {
    dependsOn tasks.named('testAggregateTestReport', TestReport)
}

build.dependsOn subprojects.build

tasks.register('buildCI') { dependsOn build, javadocAll /*, asciidoctor */ }

tasks.named('installDist').configure {
    destinationDir = layout.buildDirectory.dir('artifacts').get().getAsFile()
}

distributions {
    main {
        contents {
            project.subprojects.each { sub ->
                into(sub.name) {
                    from sub.jar
                    from sub.sourcesJar
                    from sub.javadocJar
                    from sub.generatePomFileForJarPublication
                    from sub.generateMetadataFileForJarPublication
                }
            }
        }
    }
}