LIB_PLC/FbSoftPWM.SCL at main · DIYPLC/LIB_PLC · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
FUNCTION_BLOCK "FbSoftPWM"
TITLE = 'ØÈÌ ãåíåðàòîð äâóõêàíàëüíûé.'

{ S7_read_back := 'true' ;
  S7_blockview := 'big'  }

AUTHOR  : VA
FAMILY  : LIB_PLC
VERSION : '2.1'

VAR_INPUT // Âõîäíûå ïåðåìåííûå, ñîõðàíÿåìûå.
DutyCucle      :REAL := 50.0;   // Êîýôôèöèåíò çàïîëíåíèÿ -100...0...100 [%].
PeriodPositive :REAL := 10.0;   // Ïåðèîä ØÈÌ äëÿ ïîëîæèòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
PeriodNegative :REAL := 10.0;   // Ïåðèîä ØÈÌ äëÿ îòðèöàòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
DBMAX          :REAL := 0.001;  // dead band - Çîíà íå÷óâñòâèòåëüíîñòè, âåðõíÿÿ ãðàíèöà [%].
DBMIN          :REAL := -0.001; // dead band - Çîíà íå÷óâñòâèòåëüíîñòè, íèæíÿÿ ãðàíèöà [%].
Ts             :REAL := 0.1;    // Øàã äèñêðåòèçàöèè ïî âðåìåíè [ñ].
END_VAR

VAR_OUTPUT // Âûõîäíûå ïåðåìåííûå, ñîõðàíÿåìûå.
PWMPOS :BOOL := FALSE; // Âûõîä ØÈÌ äëÿ ïîëîæèòåëüíûõ çíà÷åíèé âõîäà.
PWMNEG :BOOL := FALSE; // Âûõîä ØÈÌ äëÿ îòðèöàòåëüíûõ çíà÷åíèé âõîäà.
END_VAR

VAR // Âíóòðåííèå ïåðåìåííûå, ñîõðàíÿåìûå.
TimerPositive :REAL := 0.0; // Òàéìåð äëÿ ïîëîæèòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
TimerNegative :REAL := 0.0; // Òàéìåð äëÿ îòðèöàòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
END_VAR

VAR_TEMP // Âðåìåííûå ïåðåìåííûå, íå ñîõðàíÿåìûå.
Percent           :REAL; // Âõîäíîé ñèãíàë ïîñëå çîíû íå÷óâñòâèòåëüíîñòè è àìïëèòóäíîãî îãðàíè÷èòåëÿ -100...0...100[%].
TimePulsePositive :REAL; // Âðåìÿ èìïóëüñà äëÿ ïîëîæèòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
TimePulseNegative :REAL; // Âðåìÿ èìïóëüñà äëÿ îòðèöàòåëüíîãî êîýôôèöèåíòà çàïîëíåíèÿ [ñ].
END_VAR

BEGIN

// ØÈÌ ãåíåðàòîð äâóõêàíàëüíûé.
//            DbSoftPWM
//     +---------------------+
//     |      FbSoftPWM      |
//  ->-|DutyCucle      PWMPOS|->-
//    -|PeriodPositive PWMNEG|->-
//    -|PeriodNegative       |
//    -|DBMAX                |
//    -|DBMIN                |
//    -|Ts                   |
//     +---------------------+

// Çîíà íå÷óâñòâèòåëüíîñòè äëÿ âõîäíîãî ñèãíàëà.
IF ((DBMIN<DutyCucle)AND(DutyCucle<DBMAX)) THEN
Percent:=0.0;
ELSE
Percent:=DutyCucle;
END_IF;

// Àìïëèòóäíûé îãðàíè÷èòåëü âõîäíîãî ñèãíàëà îò -100% äî 100%.
IF (Percent>=100.0) THEN
Percent:=100.0;
END_IF;
IF (Percent<=-100.0) THEN
Percent:=-100.0;
END_IF;

// Ôîðìèðîâàíèå èìïóëüñîâ íà îòêðûòèå.
IF (Percent>0.0) THEN
PWMNEG:=FALSE;
TimerNegative:=0.0;
TimePulsePositive:=PeriodPositive*Percent*0.01;
    IF (TimerPositive<=TimePulsePositive) THEN
    PWMPOS:=TRUE;
    ELSE
    PWMPOS:=FALSE;
    END_IF;
TimerPositive:=TimerPositive+Ts;
    IF (TimerPositive>=PeriodPositive) THEN
    TimerPositive:=0.0;
    END_IF;
END_IF;

// Ôîðìèðîâàíèå èìïóëüñîâ íà çàêðûòèå.
IF (Percent<0.0) THEN
PWMPOS:=FALSE;
TimerPositive:=0.0;
TimePulseNegative:=PeriodNegative*Percent*(-0.01);
    IF (TimerNegative<=TimePulseNegative) THEN
    PWMNEG:=TRUE;
    ELSE
    PWMNEG:=FALSE;
    END_IF;
TimerNegative:=TimerNegative+Ts;
    IF (TimerNegative>=PeriodNegative) THEN
    TimerNegative:=0.0;
    END_IF;
END_IF;

// Íåò èìïóëüñîâ.
IF (Percent=0.0) THEN
PWMPOS:=FALSE;
PWMNEG:=FALSE;
TimerPositive:=0.0;
TimerNegative:=0.0;
END_IF;

// @COPYLEFT ALL WRONGS RESERVED :)
// Author: VA
// Contacts: DIY.PLC.314@gmail.com
// Date start LIB_PLC: 2014
// License: GNU GPL-2.0-or-later
// https://www.gnu.org/licenses/old-licenses/gpl-2.0.html
// https://www.youtube.com/watch?v=n1F_MfLRlX0
// https://www.youtube.com/@DIY_PLC
// https://github.com/DIYPLC/LIB_PLC
// https://oshwlab.com/diy.plc.314/PLC_HW1_SW1
// https://3dtoday.ru/3d-models/mechanical-parts/body/korpus-na-din-reiku
// https://t.me/DIY_PLC
// https://drive.google.com/drive/folders/16GDX0i07rwDrl_oPzL-lQAqMiAz3ouJV?usp=sharing

END_FUNCTION_BLOCK