rtl8152-led-ctrl/flake.nix at main · EHfive/rtl8152-led-ctrl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    naersk = {
      url = "github:nix-community/naersk";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, naersk, ... }:
    let
      forAllSystems = nixpkgs.lib.genAttrs [ "x86_64-linux" "x86_64-darwin" "i686-linux" "aarch64-linux" "aarch64-darwin" ];

      package = { pkgs, lib, stdenv }:
        let
          hostCargoEnvVarTarget = stdenv.hostPlatform.rust.cargoEnvVarTarget;
          hostCargoEnvVarTargetLower = lib.toLower hostCargoEnvVarTarget;
          hostCC = pkgs.rust.envVars.linkerForHost;
        in
        (pkgs.callPackage naersk { }).buildPackage {
          src = ./.;

          nativeBuildInputs = with pkgs; [
            pkg-config
          ];
          buildInputs = with pkgs; [
            libusb1
          ];
          strictDeps = true;

          "CC_${hostCargoEnvVarTargetLower}" = hostCC;
          "CARGO_TARGET_${hostCargoEnvVarTarget}_LINKER" = hostCC;
        };

      overlay = final: prev: {
        rtl8152-led-ctrl = prev.callPackage package { };
      };

      defaultModule = {
        imports = [
          # TODO: add udev rules to setup LED configuration on USB device plug-in
          {
            nixpkgs.overlays = [ overlay ];
          }
        ];
      };
    in
    {
      overlays.default = overlay;
      nixosModules.default = defaultModule;

      packages = forAllSystems (system:
        let
          pkgs = import nixpkgs {
            inherit system;
          };
        in
        {
          default = pkgs.callPackage package { };
          default-aarch64 = pkgs.pkgsCross.aarch64-multiplatform.callPackage package { };
        }
      );

      legacyPackages = forAllSystems (system:
        import nixpkgs {
          inherit system;
          overlays = [ overlay ];
          crossOverlays = [ overlay ];
        }
      );
    };
}