Godot addon (Steam version of Godot only): Input lag in script editor when the plugin is turned on

[GabiAioi]

When using Godot from Steam along with the GDScript Formatter (GDQuest) plugin, writing anything in Godot's code editor becomes extremely laggy and has a very high input lag, and I don't know why.

[NathanLovato]

If you haven't already, could you please try these steps? go to the project settings and in the plugins tab deactivate the plugin then use the editor for a bit. does it stay slow? And then try reactivating the plugin once more without leaving the do? Does anything change?

Normally the plugin does not do anything in real time. So it shouldn't affect your editor performance. The main things it does are registering some new commands in the editor and inserting a new menu in the script editor.

[GabiAioi]

This problem only occurs in the Steam version of Godot 4.7, and with the plugin enabled. As shown in the video, when the plugin is enabled, typing even slightly fast (or very fast) causes the editor to lag, making it clear that Godot is slow to identify the inputs (this only happens in the script section). I did the exact same test on a non-Steam version of Godot, and this didn't happen, so it's a very bizarre problem.

I forgot to add this detail, but if I use the plugin in the normal version of Godot, no problem occurs, but if I add Godot as a "non-Steam game" and run Godot through Steam, the problem happens again.

0001-1525.mp4

[NathanLovato]

Thanks for sharing the video clip. That's an interesting issue. I have no idea what could be causing it unfortunately! I'll see if I can think of something but can't make promises there.

[GabiAioi]

@NathanLovato I just discovered that this problem is worse than it seems, as it doesn't only happen in the script editor, it happens in other places as well, as demonstrated in the video below.

But detailing the problem in text, in the 2D Editor, when holding "ctrl" and scrolling the mouse wheel up/down, the editor becomes extremely laggy, and it also happens when holding "ctrl + shift" and scrolling the mouse wheel.

And the problem of lag while typing doesn't only happen in Script Tab, but in several things that involve typing text in the editor.

All this is still only in the Steam version.

0001-6319.mp4

[ZhoraGlueman]

I think I found the issue.
When you press a key, _shortcut_input() in addons/GDQuest_GDScript_formatter/plugin.gd (the script of this addon that is responsible for formatting) is called. _shortcut_input() is overwritten like this (line 135):

func _shortcut_input(event: InputEvent) -> void:
	if not has_command(get_editor_setting(SETTING_FORMATTER_PATH)):
		return
	var shortcut := get_editor_setting(SETTING_SHORTCUT) as Shortcut
	if not is_instance_valid(shortcut):
		return
	if shortcut.matches_event(event) and event.is_pressed() and not event.is_echo():
		if format_current_script():
			get_tree().root.set_input_as_handled()

First if calls has_command() (line 431):

func has_command(command: String) -> bool:
	if command.is_empty():
		return false
	var output: Array = []
	var exit_code := OS.execute(command, ["--version"], output)
	return exit_code == OK

And here is the issue.
Every time a keyboard input is registered (when you hold a key, it sends tens or hundreds of inputs per second), this method starts a new process via OS.execute(), that is blocking the main thread (check Official GDScript documentation for more info). This is causing the lags.

Here is the solution that I found. Either rewrite _shortcut_input() like this, so has_command() is called only when you press a specified shortcut for formatting:

func _shortcut_input(event: InputEvent) -> void:
	var shortcut := get_editor_setting(SETTING_SHORTCUT) as Shortcut
	if not is_instance_valid(shortcut):
		return
	if not shortcut.matches_event(event) or not event.is_pressed() or event.is_echo():
		return
	if not has_command(get_editor_setting(SETTING_FORMATTER_PATH)):
		return
	if format_current_script():
		get_tree().root.set_input_as_handled()

or rewrite has_command() so it just checks if the specified formatter executable exists:

func has_command(command: String) -> bool:
	if command.is_empty():
		return false
	return FileAccess.file_exists(command)

I prefer rewriting both methods (don't really see why would you need to run an executable to check if it exists).

This worked for me. I'm new to Godot and GDScript, so if this solution is not good, I would be glad to know why.

P.S. I'm using the Steam version. Haven't checked if I have the same issue in the non-Steam version