dots/flake.nix at main · HexExecute/dots · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    flake-utils.url = "github:numtide/flake-utils";
    stylix = {
      url = "github:danth/stylix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    caelestia-cli = {
      url = "github:caelestia-dots/cli";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    caelestia-shell = {
      url = "github:caelestia-dots/shell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      flake-utils,
      stylix,
      caelestia-cli,
      caelestia-shell,
      zen-browser,
      ...
    }@inputs:
    let
      system = "x86_64-linux";
      username = "hex";
      stateVersion = "25.11";

      makeNixosSystem =
        hostName: systemFile: homeFile:
        nixpkgs.lib.nixosSystem {
          inherit system;
          modules = [
            systemFile
            stylix.nixosModules.stylix
            home-manager.nixosModules.home-manager
            {
              nixpkgs.overlays = [ (import ./overlays system inputs) ];
              nixpkgs.config.allowUnfree = true;

              home-manager = {
                useGlobalPkgs = true;
                useUserPackages = true;
                backupFileExtension = "bak";
                users.${username} = import homeFile;
                extraSpecialArgs = {
                  inherit
                    inputs
                    hostName
                    username
                    stateVersion
                    ;
                };
              };
            }
          ];
          specialArgs = {
            inherit
              inputs
              hostName
              username
              stateVersion
              ;
          };
        };
    in
    {
      nixosConfigurations = {
        "${username}-laptop" = makeNixosSystem "${username}-laptop" ./system/laptop ./home/laptop;
        "${username}-desktop" = makeNixosSystem "${username}-desktop" ./system/desktop ./home/desktop;
        "${username}-vm" = makeNixosSystem "${username}-vm" ./system/vm ./home/vm;
      };
    };
}