nixos/flake.nix at master · MandoCoding/nixos · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
{
  description = "System configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    apple-fonts.url = "github:Lyndeno/apple-fonts.nix";
    thyx.url = "github:rccyx/thyx";
    eagle.url = "github:Naitrate/Eagle-Linux";

    zen-browser = {
      url = "github:youwen5/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs@{ nixpkgs, nixpkgs-unstable, zen-browser, thyx, ... }:
    let
      system = "x86_64-linux";

      pkgs-unstable = import nixpkgs-unstable {
        inherit system;
        config.allowUnfree = true;
      };

      mkHost = hostPath:
        nixpkgs.lib.nixosSystem {
          inherit system;

          modules = [
            hostPath
            thyx.nixosModules.default

            {
              services.displayManager.sddm.enable = true;
              services.displayManager.sddm.wayland.enable = true;
              services.displayManager.sddm.thyx.enable = true;
            }
          ];

          specialArgs = {
            inherit inputs pkgs-unstable;
            zenBrowser = zen-browser;
          };
        };
    in
    {
      nixosConfigurations = {
        desktop-home = mkHost ./hosts/desktop-home/configuration.nix;
        desktop-work = mkHost ./hosts/desktop-work/configuration.nix;
        laptop-home = mkHost ./hosts/laptop-home/configuration.nix;
      };
    };
}