home-manager/flake.nix at main · Notarin/home-manager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
{
  description = "Home Manager configuration for Notarin";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    stylix = {
      url = "github:danth/stylix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixcord = {
      url = "github:kaylorben/nixcord";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-vscode-extensions = {
      url = "github:nix-community/nix-vscode-extensions";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
    ...
  }: let
    systems = ["x86_64-linux"];
    buildAllSystems = output: builtins.foldl' nixpkgs.lib.recursiveUpdate {} (map output systems);
  in
    buildAllSystems (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};
      in {
        formatter.${system} = pkgs.callPackage ./formatter.nix {};
        checks.${system}.formatting = self.formatter.${system};
        packages.${system} = import ./packages pkgs;
        homeConfigurations = {
          notarin = home-manager.lib.homeManagerConfiguration {
            inherit pkgs;
            extraSpecialArgs = {inherit self;};
            modules = [./homeManagerModules];
          };
          "notarin@uriel" = home-manager.lib.homeManagerConfiguration {
            inherit pkgs;
            extraSpecialArgs = {inherit self;};
            modules = [
              ./homeManagerModules
              {config.host = "uriel";}
            ];
          };
          root = home-manager.lib.homeManagerConfiguration {
            inherit pkgs;
            extraSpecialArgs = {inherit self;};
            modules = [
              ./homeManagerModules
              {home.username = "root";}
            ];
          };
        };
      }
    );
}