OGResize/build.gradle at main · OGCraftMC/OGResize · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
plugins {
    id 'java'
    id "xyz.jpenilla.run-paper" version "2.3.1"
    id 'com.gradleup.shadow' version '9.3.1'
    id "io.papermc.paperweight.userdev" version "2.0.0-beta.24"
}

group = 'org.ogcraft.resize'
version = '1.5'

jar {
    archiveBaseName.set("OGResize")
}

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
}

dependencies {
    paperweight.paperDevBundle("26.3.build.+")
    implementation("org.bstats:bstats-bukkit:3.2.1")
}

tasks {
    runServer {
        minecraftVersion("26.3")
    }
}

def targetJavaVersion = 25
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    configurations = [project.configurations.runtimeClasspath]

    dependencies {
        exclude {
            it.moduleGroup != 'org.bstats'
        }
    }

    relocate 'org.bstats', 'org.ogcraft.resize.libs.bstats'
}