RandomFishing/build.gradle at master · Overcontrol1/RandomFishing · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
plugins {
	id 'fabric-loom' version '1.9-SNAPSHOT'
	id 'maven-publish'
	id "me.modmuss50.mod-publish-plugin" version "0.5.1"
	id "com.sidneysimmons.gradle-plugin-external-properties" version "2.0.1"
	id "dev.kikugie.j52j" version "1.0"
}

minecraft_version = stonecutter.current.version

version = "${project.mod_version}-${minecraft_version}"
group = project.maven_group


base {
	archivesName = project.archives_base_name
}

repositories {
	maven { url 'https://maven.nucleoid.xyz' }
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	if (stonecutter.eval(minecraft_version, "<1.21")) {
		include modImplementation("eu.pb4:polymer-core:${project.polymer_version}")
		include modImplementation("xyz.nucleoid:server-translations-api:${project.server_translations_version}")
	}
}


processResources {
	inputs.property "version", project.property("mod_version")
	inputs.property "minecraft_version", minecraft_version
	inputs.property "polymer_version", project.property("polymer_version")
	inputs.property "server_translations_version", project.property("server_translations_version")

	filesMatching("fabric.mod.json5") {
		expand ([
				"version": project.property("mod_version"),
				"minecraft_version": minecraft_version,
				"polymer_version": project.property("polymer_version"),
				"server_translations_version": project.property("server_translations_version")
		])
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

jar {


	from("LICENSE") {
		rename { "${it}_${project.base.archivesName.get()}"}
	}
}

loom {
	runConfigs.all {
		ideConfigGenerated true // Run configurations are not created for subprojects by default
		runDir "../../run" // Use a shared run folder and just create separate worlds
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

publishMods {
	file = remapJar.archiveFile

	type = STABLE
	modLoaders.add("fabric")
	additionalFiles.from(remapSourcesJar.archiveFile)

	displayName = "Random Fishing " + project.version

	modrinth {
		accessToken = props.get("MODRINTH_KEY")
		projectId = "vEyyiUWA"
		minecraftVersions.add(minecraft_version)
	}

	github {
		accessToken = props.get("GITHUB_TOKEN")
		repository = "Overcontrol1/RandomFishing"
		commitish = "master"
		tagName = project.version
	}

	changelog = rootProject.file("CHANGELOG.md").text
}