SConscript

# -*-python-*-

Import("env")

cppenv = env.Clone(tools = ['cpp'])

cppenv.AppendUnique(CPPDEFINES = ['LIBSTATISKIT_CORE'])

exclude = """
""".split()

sources = [source for source in cppenv.Glob('*.h*') if not source.name in exclude]
targets = cppenv.CppDev(["statiskit", "core"], sources)
Alias("cpp-dev", targets)
Alias("cpp", targets)
Alias("autowig", targets)
Alias("install", targets)

wigenv = cppenv.Clone(tools = ['wig'])
wigenv.AppendUnique(CPPDEFINES=['EIGEN_NO_STATIC_ASSERT', 'AUTOWIG'])
targets = wigenv.BoostPythonWIG('statiskit_core', [target for target in targets if target.name.endswith('.h')],
                                module='../py/wrapper/_core.cpp',
                                decorator='../py/statiskit/core/_core.py',
                                parser_bootstrap=1,
                                controller='AutoWIG.py',
                                depends=['statiskit_linalg'])
Alias("autowig", targets)
wigenv.Depends(targets, "cpp-dev")

exclude = """
""".split()

sources = [source for source in cppenv.Glob('*.cpp') if not source.name in exclude]
targets = cppenv.CppLib("statiskit_core", sources)
Alias("cpp-lib", targets)
Alias("cpp", targets)
Alias("install", targets)