BeeBEEP/beebeep.pri at main · Stkai/BeeBEEP · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

win32-msvc: {
  QMAKE_LFLAGS += /INCREMENTAL:NO
  lessThan( QT_MAJOR_VERSION, 5) | lessThan(QT_MINOR_VERSION, 10) {
    QMAKE_LFLAGS_WINDOWS = /SUBSYSTEM:WINDOWS,5.01
  } else {
    QMAKE_LFLAGS_WINDOWS = /SUBSYSTEM:WINDOWS
  }
}

INCLUDEPATH += $$PWD/src $$PWD/src/core
DESTDIR = $$PWD/test

unix:!macx:!android: {
  CONFIG(debug,debug|release) {
    OBJECTS_DIR = $$PWD/build/debug/qt-$$QT_VERSION-$$QMAKE_HOST.arch
  } else {
    OBJECTS_DIR = $$PWD/build/release/qt-$$QT_VERSION-$$QMAKE_HOST.arch
  }

  UI_DIR = $$OBJECTS_DIR
  MOC_DIR = $$OBJECTS_DIR
  RCC_DIR = $$OBJECTS_DIR

  isEmpty(PREFIX) {
    PREFIX = /usr/local
  }
  isEmpty(BINDIR) {
    BINDIR = $$PREFIX/bin
  }
  isEmpty(DATADIR) {
    DATADIR = $$PREFIX/share
  }
  isEmpty(PLUGINDIR) {
    PLUGINDIR = $$PREFIX/lib/beebeep
  }

  data.files = locale/*.qm src/images/beebeep.png misc/beep.wav
  data.path = $$DATADIR/beebeep/

  desktop.files = scripts/debian_amd64/beebeep.desktop
  desktop.path = $$DATADIR/applications/

  appdata.files = scripts/debian_amd64/beebeep.appdata.xml
  appdata.path = $$DATADIR/metainfo/

  INSTALLS += data desktop appdata
}