OctoFishstick/meson.build at main · StynH/OctoFishstick · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
project('OctoFishstick', 'c',
  meson_version: '>=0.60',
  default_options: ['c_std=c23', 'buildtype=debugoptimized', 'warning_level=3'],
)

gnome = import('gnome')
cc = meson.get_compiler('c')
if cc.get_id() == 'clang'
  add_project_arguments('-Wall', '-Wextra', '-Wpedantic', '-Werror', language: 'c')
endif

deps = [
  dependency('gtk4', required: true),
  dependency('glib-2.0', required: true),
  dependency('gobject-2.0', required: true),
  dependency('cairo', required: true),
  dependency('json-c', required: true),
  dependency('libcurl', required: true),
  dependency('gee-0.8', required: true),
]

livechart_inc = include_directories('external/live-chart-c')
livechart_dir = join_paths(meson.project_source_root(), 'external', 'live-chart-c')
livechart     = cc.find_library('livechart', dirs: [livechart_dir], required: true)

libm = cc.find_library('m', required: false)

sources = files(
    'src/actions.c',
    'src/api.c',
    'src/resources.c',
    'src/app.c',
    'src/main.c',
    'src/user.c',
    'src/window.c',

    'src/views/add_ticker_dialog.c',
    'src/views/watchlist.c',
    'src/views/footer.c',

    'src/helpers/widget_helpers.c',
    'src/helpers/time_helpers.c',
    'src/helpers/string_helpers.c',

    'src/background/api_worker.c',

    'src/storage/local_storage.c'
)

all_deps = deps + [livechart]
if libm.found()
  all_deps += libm
endif

gresources = gnome.compile_resources(
  'octofishstick-resources',
  'resources/octofishstick.gresource.xml',
  source_dir: 'resources',
  c_name: 'octo_fishstick'
)

executable('OctoFishstick', sources + gresources,
  dependencies: all_deps,
  include_directories: [livechart_inc],
  install: false,
)