build.gradle

plugins {
    id 'java'
    id("xyz.jpenilla.run-paper") version "2.3.1"
    id("com.gradleup.shadow") version "9.3.1"
}

group = 'tech.techstreet.border'
version = '2.0.3'
build.dependsOn shadowJar

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
}

dependencies {
    implementation("cloud.commandframework:cloud-paper:1.5.0")                  // Cloud Paper Framework
    implementation("cloud.commandframework:cloud-minecraft-extras:1.5.0")       // Cloud Extras
    implementation("org.bstats:bstats-bukkit:3.1.0")                            // bStats Metrics

    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")
}

tasks {
    runServer {
        // Configure the Minecraft version for our task.
        // This is the only required configuration besides applying the plugin.
        // Your plugin's jar (or shadowJar if present) will be used automatically.
        minecraftVersion("1.21")
    }
}

def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.shadowJar {
    archiveBaseName.set(project.name)
    archiveClassifier.set("all")

    relocate("org.bstats", "tech.techstreet.border.shadow.bstats")
    from("LICENSE") { into("") }
    from(sourceSets.main.output)

    manifest {
        attributes(
                "Implementation-Title": project.name,
                "Implementation-Version": project.version,
                "License": "AGPL-3.0-or-later",
                "License-URL": "https://www.gnu.org/licenses/agpl-3.0.html"
        )
    }

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}