stable-fluids/CMakeLists.txt at master · Xayah-Graphics/stable-fluids · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
cmake_minimum_required(VERSION 4.3.0)
set(CMAKE_EXPERIMENTAL_CXX_IMPORT_STD "451f2fe2-a8a2-47c3-bc32-94786d8fc91b")
project(stable-fluids VERSION 1.0.0 LANGUAGES CXX CUDA)

option(SMOKE_BUILD_BENCHMARK "Build benchmark applications" OFF)
option(SMOKE_BUILD_VULKAN_APP "Build Vulkan sample application" OFF)

# ============================================================================
# C++ Configuration
# ============================================================================
set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS ON)
set(CMAKE_EXPERIMENTAL_CXX_MODULE_CMAKE_API ON)
set(CMAKE_CXX_SCAN_FOR_MODULES ON)


# ============================================================================
# CUDA Configuration
# ============================================================================
set(CMAKE_CUDA_STANDARD 20)
set(CMAKE_CUDA_STANDARD_REQUIRED ON)
set(CMAKE_CUDA_EXTENSIONS OFF)
set(CMAKE_CUDA_ARCHITECTURES 120)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)


# ============================================================================
# Libraries
# ============================================================================
find_package(CUDAToolkit REQUIRED)
add_library(stable-fluids SHARED)
target_sources(
        stable-fluids
        PRIVATE
        backend-cuda.cu
        PUBLIC
        stable-fluids-3d.h
)
target_link_libraries(stable-fluids PRIVATE CUDA::cudart)
target_include_directories(stable-fluids PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
target_compile_definitions(stable-fluids PRIVATE STABLE_FLUIDS_BUILD_SHARED)
target_compile_options(stable-fluids PRIVATE $<$<COMPILE_LANGUAGE:CUDA>:--extended-lambda --expt-relaxed-constexpr>)
if (MSVC)
    target_compile_options(stable-fluids PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/W4 /permissive- /Zc:preprocessor>)
    target_compile_options(stable-fluids PRIVATE $<$<COMPILE_LANGUAGE:CUDA>:-Xcompiler=/Zc:preprocessor>)
else ()
    target_compile_options(stable-fluids PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Wall -Wextra -Wpedantic>)
endif ()


# ============================================================================
# Samples
# ============================================================================
if (SMOKE_BUILD_BENCHMARK)
    add_executable(stable-fluids-benchmark benchmark.cu)
    target_link_libraries(stable-fluids-benchmark PRIVATE stable-fluids CUDA::cudart)
    target_compile_options(stable-fluids-benchmark PRIVATE $<$<COMPILE_LANGUAGE:CUDA>:--extended-lambda --expt-relaxed-constexpr>)
    if (MSVC)
        target_compile_options(stable-fluids-benchmark PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/W4 /permissive- /Zc:preprocessor>)
        target_compile_options(stable-fluids-benchmark PRIVATE $<$<COMPILE_LANGUAGE:CUDA>:-Xcompiler=/Zc:preprocessor>)
    else ()
        target_compile_options(stable-fluids-benchmark PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Wall -Wextra -Wpedantic>)
    endif ()
endif ()


# ============================================================================
# Vulkan Sample Application
# ============================================================================
if (SMOKE_BUILD_VULKAN_APP)
    find_package(Vulkan REQUIRED)
    set(_VULKAN_HPP_IMPL "${CMAKE_CURRENT_BINARY_DIR}/_vulkan_hpp_impl.cpp")
    file(WRITE "${_VULKAN_HPP_IMPL}" [[
#include <vulkan/vulkan_raii.hpp>
VULKAN_HPP_DEFAULT_DISPATCH_LOADER_DYNAMIC_STORAGE
]])
    if (NOT TARGET glfw)
        add_subdirectory(vulkan-app/vendor/glfw)
    endif ()
    # ============================================================================
    # Shader Compilation
    # ============================================================================
    find_program(
            SLANGC_EXECUTABLE
            NAMES slangc
            HINTS ENV VULKAN_SDK
            PATH_SUFFIXES Bin bin
    )
    file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/shaders")
    set(SMOKE_SIM_SHADER_DIR "${CMAKE_CURRENT_BINARY_DIR}/shaders")
    set(SMOKE_SIM_SHADER_SOURCES
            vulkan-app/shaders/background.slang
            vulkan-app/shaders/field_plane.slang
            vulkan-app/shaders/field_volume.slang
    )
    set(SMOKE_SIM_SHADER_OUTPUTS "")
    foreach (shader IN LISTS SMOKE_SIM_SHADER_SOURCES)
        get_filename_component(shader_name "${shader}" NAME_WE)
        set(shader_output "${SMOKE_SIM_SHADER_DIR}/${shader_name}.spv")
        add_custom_command(
                OUTPUT "${shader_output}"
                COMMAND "${SLANGC_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/${shader}" -profile sm_6_5 -target spirv -entry vs_main -entry fs_main -o "${shader_output}"
                DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${shader}"
                COMMENT "Compiling ${shader_name}.slang"
                VERBATIM
        )
        list(APPEND SMOKE_SIM_SHADER_OUTPUTS "${shader_output}")
    endforeach ()
    add_custom_target(stable-fluids-shaders DEPENDS ${SMOKE_SIM_SHADER_OUTPUTS})
    # ============================================================================
    # Application
    # ============================================================================
    add_executable(stable-fluids-app)
    target_sources(stable-fluids-app
            PRIVATE
            vulkan-app/src/vk.camera.cpp
            vulkan-app/src/vk.context.cpp
            vulkan-app/src/vk.frame.cpp
            vulkan-app/src/vk.geometry.cpp
            vulkan-app/src/vk.imgui.cpp
            vulkan-app/src/vk.math.cpp
            vulkan-app/src/vk.memory.cpp
            vulkan-app/src/vk.pipeline.cpp
            vulkan-app/src/vk.swapchain.cpp
            vulkan-app/src/vk.texture.cpp
            vulkan-app/vendor/imgui/imgui.cpp
            vulkan-app/vendor/imgui/imgui_draw.cpp
            vulkan-app/vendor/imgui/imgui_tables.cpp
            vulkan-app/vendor/imgui/imgui_widgets.cpp
            vulkan-app/vendor/imgui/backends/imgui_impl_glfw.cpp
            vulkan-app/vendor/imgui/backends/imgui_impl_vulkan.cpp

            vulkan-app/main.cpp
            vulkan-app/app.cpp
            vulkan-app/scene_plume.cpp

            PUBLIC FILE_SET cxx_modules TYPE CXX_MODULES FILES
            vulkan-app/modules/vk.camera.ixx
            vulkan-app/modules/vk.context.ixx
            vulkan-app/modules/vk.frame.ixx
            vulkan-app/modules/vk.geometry.ixx
            vulkan-app/modules/vk.imgui.ixx
            vulkan-app/modules/vk.math.ixx
            vulkan-app/modules/vk.memory.ixx
            vulkan-app/modules/vk.pipeline.ixx
            vulkan-app/modules/vk.swapchain.ixx
            vulkan-app/modules/vk.texture.ixx
            vulkan-app/app.ixx
            vulkan-app/scene_plume.ixx
    )
    add_dependencies(stable-fluids-app stable-fluids-shaders)
    target_compile_definitions(stable-fluids-app PRIVATE SMOKE_SIM_SHADER_DIR="${SMOKE_SIM_SHADER_DIR}" VULKAN_HPP_DISPATCH_LOADER_DYNAMIC=1 VULKAN_HPP_NO_STRUCT_CONSTRUCTORS=1)
    target_link_libraries(stable-fluids-app PRIVATE Vulkan::Vulkan glfw stable-fluids CUDA::cudart)
    target_include_directories(stable-fluids-app PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/vulkan-app/vendor/imgui)
    set_property(TARGET stable-fluids-app PROPERTY CXX_MODULE_STD ON)
    set_target_properties(stable-fluids-app PROPERTIES CUDA_SEPARABLE_COMPILATION ON CUDA_RESOLVE_DEVICE_SYMBOLS ON)
    if (MSVC)
        target_compile_options(stable-fluids-app PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/W4 /permissive- /Zc:preprocessor>)
    endif ()
endif ()