microbus/CMakeLists.txt at master · alkavan/microbus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
cmake_minimum_required(VERSION 3.21)
project(microbus VERSION 1.1.1 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

add_library(microbus INTERFACE)

target_include_directories(microbus INTERFACE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
        $<INSTALL_INTERFACE:include>
)

target_compile_features(microbus INTERFACE cxx_std_17)

# Define installation directory for headers
set(INCLUDE_INSTALL_DIR include)

# Create examples executable and link it to microbus
add_executable(microbus_examples src/examples.cpp)
target_include_directories(microbus_examples PRIVATE include)
target_link_libraries(microbus_examples microbus)

### EXPORT #####################################################################

install(TARGETS microbus
        EXPORT microbusTargets
        LIBRARY DESTINATION lib
        ARCHIVE DESTINATION lib
        RUNTIME DESTINATION bin
        INCLUDES DESTINATION include
)

install(FILES include/microbus.hpp DESTINATION include)

install(EXPORT microbusTargets
        FILE microbusTargets.cmake
        NAMESPACE microbus::
        DESTINATION lib/cmake/microbus
)

# Create a package config file
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
        microbusConfigVersion.cmake
        VERSION ${PROJECT_VERSION}
        COMPATIBILITY SameMajorVersion
)

configure_package_config_file(
        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/microbusConfig.cmake.in"
        "${CMAKE_CURRENT_BINARY_DIR}/microbusConfig.cmake"
        INSTALL_DESTINATION lib/cmake/microbus
        PATH_VARS
        INCLUDE_INSTALL_DIR
)

install(FILES
        "${CMAKE_CURRENT_BINARY_DIR}/microbusConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/microbusConfigVersion.cmake"
        DESTINATION lib/cmake/microbus
)