zigzag/flake.nix at main · arkan/zigzag · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
{
  description = "Zigzag - TUI/CLI project manager for Zellij";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };
        rustToolchain = pkgs.rust-bin.fromRustupToolchain {
          channel = "1.95.0";
          components = [ "clippy" "rustfmt" "rust-src" "rust-analyzer" ];
          targets = [ "wasm32-wasip1" ];
        };
        rustPlatform = pkgs.makeRustPlatform {
          cargo = rustToolchain;
          rustc = rustToolchain;
        };
        zigzagPackage = pkgs.callPackage ./package.nix { inherit rustPlatform; };
        zigzagApp = {
          type = "app";
          program = "${zigzagPackage}/bin/zigzag";
          meta = zigzagPackage.meta;
        };
      in
      {
        packages = {
          default = zigzagPackage;
          zigzag = zigzagPackage;
        };

        apps = {
          default = zigzagApp;
          zigzag = zigzagApp;
        };

        devShells.default = pkgs.mkShell {
          buildInputs = [
            rustToolchain
            pkgs.cargo-watch
            pkgs.nodejs_22
            pkgs.zellij
            pkgs.gnumake
          ];

          shellHook = ''
            echo "zigzag dev shell ready — rust $(rustc --version | cut -d' ' -f2), node $(node --version)"
          '';
        };
      }
    );
}