nixtml/flake.nix at main · arnarg/nixtml · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
{
  description = "Static website generator implemented in nix.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    {
      lib = import ./lib.nix;
      libTests = import ./lib/tests.nix { nixpkgslib = nixpkgs.lib; };
    }
    // (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
      in
      {
        packages = {
          docs = self.lib.evalModules {
            inherit pkgs;
            modules = [ ./docs ];
          };
          examples = {
            simple = self.lib.evalModules {
              inherit pkgs;
              modules = [ ./examples/simple ];
            };
            blog = self.lib.evalModules {
              inherit pkgs;
              modules = [ ./examples/blog ];
            };
          };
        };

        apps = {
          # Runs lib unit tests
          libTests = {
            type = "app";
            program =
              (pkgs.writeShellScript "lib-unit-tests" ''
                set -eo pipefail

                ${pkgs.nix-unit}/bin/nix-unit \
                  --extra-experimental-features flakes \
                  --flake "${self}#libTests"
              '').outPath;
          };

          # Runs statix for linting the nix code
          staticCheck = {
            type = "app";
            program =
              (pkgs.writeShellScript "static-lint-check" ''
                set -eo pipefail

                ${pkgs.statix}/bin/statix check .
              '').outPath;
          };

          # Quickly build and serve docs
          serveDocs = {
            type = "app";
            program =
              let
                nested = pkgs.linkFarm "nixtml-docs-nested" [
                  {
                    name = "nixtml";
                    path = self.packages.${system}.docs;
                  }
                ];
              in
              (pkgs.writeShellScript "serve-docs" ''
                ${pkgs.python3}/bin/python -m http.server -d ${nested} 8080
              '').outPath;
          };
        };
      }
    ));
}