build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.6'
    id 'io.spring.dependency-management' version '1.1.6'
    id "org.springdoc.openapi-gradle-plugin" version '1.9.0'
}

ext {
    set('springCloudVersion', "2023.0.4")
}

group = 'org.sesac'

bootJar {
    archiveFileName = 'service-order.jar'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    // lombok
    implementation 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // spring cloud
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign'
    implementation 'org.springframework.cloud:spring-cloud-starter-loadbalancer'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.cloud:spring-cloud-starter'
    implementation 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-client'
    // implementation 'org.springframework.cloud:spring-cloud-starter-config'
    implementation 'org.springframework.cloud:spring-cloud-starter-bootstrap'
    implementation 'org.springframework.cloud:spring-cloud-starter-kubernetes-client'

    // database
    runtimeOnly 'com.mysql:mysql-connector-j'

    // jpa
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    annotationProcessor 'jakarta.persistence:jakarta.persistence-api'
    annotationProcessor 'jakarta.annotation:jakarta.annotation-api'
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    // modelmapper
    implementation 'org.modelmapper:modelmapper:+'
    implementation 'org.modelmapper:modelmapper-module-record:+'

    // querydsl
    implementation 'com.querydsl:querydsl-jpa:5.+:jakarta'
    annotationProcessor 'com.querydsl:querydsl-apt:5.+:jakarta'

    // api documentation
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.6.0'

    // yaml exception messages
    implementation 'dev.akkinoc.util:yaml-resource-bundle:2.+'

    // hypersistence utils for tsid generator
    implementation 'io.hypersistence:hypersistence-utils-hibernate-63:3+'

    // log
    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'io.micrometer:micrometer-registry-prometheus'
    implementation 'io.zipkin.reporter2:zipkin-reporter-brave'
    implementation 'io.micrometer:micrometer-tracing-bridge-brave'
    implementation 'io.micrometer:micrometer-registry-otlp'
    implementation 'io.zipkin.contrib.otel:encoder-brave:0.1.0'
    runtimeOnly 'com.github.loki4j:loki-logback-appender:1.5.2'
    implementation "io.opentelemetry.instrumentation:opentelemetry-spring-boot-starter"

    implementation 'io.opentelemetry:opentelemetry-api:1.27.0'
    implementation 'io.opentelemetry:opentelemetry-context:1.27.0'
    implementation 'io.opentelemetry:opentelemetry-sdk:1.27.0'
    implementation 'io.opentelemetry:opentelemetry-sdk-metrics:1.27.0'
    implementation 'io.micrometer:micrometer-core'

    // kafka
    implementation 'org.springframework.kafka:spring-kafka'
    testImplementation 'org.springframework.kafka:spring-kafka-test'

    // redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    // retry
    implementation 'org.springframework.retry:spring-retry'
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:$springCloudVersion"
        mavenBom "io.opentelemetry.instrumentation:opentelemetry-instrumentation-bom:2.6.0"
    }
}

tasks.named('test') {
    useJUnitPlatform()
}

def querydslDir = "${project.projectDir}/build/generated/querydsl"

sourceSets {
    main.java.srcDirs += [querydslDir]
}

tasks.withType(JavaCompile).configureEach {
    options.getGeneratedSourceOutputDirectory().set(file(querydslDir))
}

clean.doLast {
    file(querydslDir).deleteDir()
}

openApi {
    apiDocsUrl = "http://localhost:8662/v3/api-docs"
    outputDir = file("${project.projectDir}/docs")
    outputFileName = "openapi.yaml"
    waitTimeInSeconds = 30
    customBootRun {
        args.set(["--spring.profiles.active=dev", "--server.port=8662"])
    }
}