justfile

set dotenv-load := true

[private]
default:
    @just --list

# Export database to backup file
backup:
    pg_dump -U postgres -h $PGHOST_PROD -p $PGPORT_PROD -W -f backups/database-{{datetime("%F")}}.bak -F t railway

psql:
    psql -U postgres -h $PGHOST_PROD -p $PGPORT_PROD -t railway

# Generate new migrations based on model changes
makemigrations:
    uv run manage.py makemigrations

# Apply database migrations
migrate:
    uv run manage.py migrate

run-postgres:
    docker compose -f docker-compose.dev.yml up -d

# Run server in development mode
run:
    uv run manage.py runserver 0.0.0.0:8888

# Run server in production mode
run-prod:
    docker/entrypoint.sh

# Seed database with dummy data
seed: migrate
    uv run manage.py seed

# Run tests
test *arguments="":
    uv run pytest {{arguments}}

# Run behavioral tests
behave arguments="":
    uv run manage.py behave {{arguments}}

# Run tests with coverage and generate data file
coverage-run:
    uv run coverage run manage.py behave
    uv run coverage run -m pytest tests/
    uv run coverage combine --quiet

[private]
coverage-html: coverage-run
    uv run coverage html

[private]
coverage-open: coverage-html
    open htmlcov/index.html

# Run tests, generate coverage HTML report, then open it in the browser
coverage: coverage-open