libb2-reforged/sources.cmake at master · deeplex/libb2-reforged · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
dplx_target_sources(libb2-reforged
    TEST_TARGET libb2-reforged-tests
    MODE SMART_SOURCE MERGED_LAYOUT
    BASE_DIR dplx

    PUBLIC
        blake2
)

dplx_target_sources(libb2-reforged
    TEST_TARGET libb2-reforged-tests
    MODE SMART_HEADER_ONLY MERGED_LAYOUT
    BASE_DIR dplx

    PUBLIC
        blake2/config
)

if (BUILD_SHARED_LIBS)
    set(DPLX_BLAKE2_STATIC_DEFINE OFF)
else()
    set(DPLX_BLAKE2_STATIC_DEFINE ON)
endif()
file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/generated/src/dplx/blake2/detail")
configure_file(tools/config.hpp.in "${CMAKE_CURRENT_BINARY_DIR}/generated/src/dplx/blake2/detail/config.hpp" @ONLY)
target_sources(libb2-reforged PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/generated/src/dplx/blake2/detail/config.hpp>)

target_sources(libb2-reforged
    PRIVATE
        src/blake2.h
        src/dplx/blake2.h
        src/dplx/blake2/detail/blake2-impl.h
        src/dplx/blake2/detail/blake2b-common.c.inc
        src/dplx/blake2/detail/blake2s-common.c.inc
        src/dplx/blake2/detail/blake2xb-generic.c
        src/dplx/blake2/detail/blake2xs-generic.c
)

set(DISPATCH_DEFS "")
foreach (IMPL IN LISTS IMPLEMENTATIONS)
    string(TOLOWER "${IMPL}" IMPL_NAME)
    list(APPEND DISPATCH_DEFS "DPLX_BLAKE2_DISPATCH_${IMPL_NAME}=$<IN_LIST:${IMPL},${ACTIVE_IMPLEMENTATIONS}>")
endforeach()
if (DPLX_BLAKE2_NO_DISPATCH)
    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/blake2-dispatch-stub.c
    )
    set_source_files_properties(
            src/dplx/blake2/detail/blake2-dispatch-stub.c

        PROPERTIES
            COMPILE_DEFINITIONS "${DISPATCH_DEFS}"
    )

else()
    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/blake2-dispatch.c
    )
    set_source_files_properties(
            src/dplx/blake2/detail/blake2-dispatch.c

        PROPERTIES
            COMPILE_FLAGS "$<$<IN_LIST:AVX,${ACTIVE_IMPLEMENTATIONS}>:${DPLX_BLAKE2_CFLAGS_XSAVE}>"
            COMPILE_DEFINITIONS "${DISPATCH_DEFS}"
    )

endif()
if ("SSE2" IN_LIST ACTIVE_IMPLEMENTATIONS
    OR "SSE41" IN_LIST ACTIVE_IMPLEMENTATIONS
    OR "AVX" IN_LIST ACTIVE_IMPLEMENTATIONS)

    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/blake2-x86-config.h
            src/dplx/blake2/detail/blake2b-x86-round.h
            src/dplx/blake2/detail/blake2s-x86-round.h

            src/dplx/blake2/detail/blake2b-sse2-load.h
            src/dplx/blake2/detail/blake2b-sse41-load.h
            src/dplx/blake2/detail/blake2s-sse2-load.h
            src/dplx/blake2/detail/blake2s-sse41-load.h
    )
endif()
if ("NEON" IN_LIST ACTIVE_IMPLEMENTATIONS)

    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/blake2b-neon-load.h
            src/dplx/blake2/detail/blake2b-neon-round.h
            src/dplx/blake2/detail/blake2s-neon-load.h
            src/dplx/blake2/detail/blake2s-neon-round.h
    )
endif()
foreach(IMPL IMPL_FILE_PART IN ZIP_LISTS ACTIVE_IMPLEMENTATIONS ACTIVE_IMPLEMENTATION_FILE_PARTS)
    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/blake2b-${IMPL_FILE_PART}.c
            src/dplx/blake2/detail/blake2s-${IMPL_FILE_PART}.c
    )
    set_source_files_properties(
        src/dplx/blake2/detail/blake2b-${IMPL_FILE_PART}.c
        src/dplx/blake2/detail/blake2s-${IMPL_FILE_PART}.c

        PROPERTIES
            COMPILE_FLAGS "${DPLX_BLAKE2_CFLAGS_${IMPL}}"
            COMPILE_DEFINITIONS "DPLX_BLAKE2_IMPL_NAME=${IMPL_FILE_PART};DPLX_BLAKE2_NO_DISPATCH=$<BOOL:${DPLX_BLAKE2_NO_DISPATCH}>"
    )
endforeach()

if (DPLX_BLAKE2_WITH_LIBB2_COMPAT)
    target_sources(libb2-reforged
        PRIVATE
            src/dplx/blake2/detail/libb2-compat.c
    )
endif()

if (BUILD_TESTING)
    dplx_target_sources(libb2-reforged-tests PRIVATE
        MODE VERBATIM
        BASE_DIR blake2_tests

        PRIVATE
            test_utils.hpp

            hex_decode.hpp
            hex_encode.hpp
            impl_id_generator.hpp
            kat_json_generator.hpp
    )

    dplx_target_data(libb2-reforged-tests
        SOURCE_DIR .

        FILES
            blake2-kat.json
        )
endif ()