Add frontend module and example

Author: wilzbach

dub.sdl

@@ -99,6 +99,7 @@ subPackage {
     "src/ddmd/escape.d" \
     "src/ddmd/expression.d" \
     "src/ddmd/expressionsem.d" \
+    "src/ddmd/frontend.d" \
     "src/ddmd/func.d" \
     "src/ddmd/hdrgen.d" \
     "src/ddmd/id.d" \

src/ddmd/frontend.d

@@ -0,0 +1,39 @@
+/**
+ * Compiler implementation of the
+ * $(LINK2 http://www.dlang.org, D programming language).
+ *
+ * This module contains high-level interfaces for interacting
+  with DMD as a library.
+ *
+ * Copyright:   Copyright (c) 1999-2017 by The D Language Foundation, All Rights Reserved
+ * Authors:     $(LINK2 http://www.digitalmars.com, Walter Bright)
+ * License:     $(LINK2 http://www.boost.org/LICENSE_1_0.txt, Boost License 1.0)
+ * Source:      $(LINK2 https://github.com/dlang/dmd/blob/master/src/ddmd/id.d, _id.d)
+ */
+module ddmd.frontend;
+
+// Online documentation: https://dlang.org/phobos/ddmd_frontend.html
+
+/**
+Initializes the DMD compiler
+*/
+void initDMD()
+{
+    import ddmd.globals : global;
+    import ddmd.dmodule : Module;
+    import ddmd.id : Id;
+    import ddmd.mtype : Type;
+    import ddmd.target : Target;
+    import ddmd.expression : Expression;
+    import ddmd.objc : Objc;
+    import ddmd.builtin : builtin_init;
+
+    Type._init();
+    Id.initialize();
+    Module._init();
+    Target._init();
+    Expression._init();
+    Objc._init();
+    builtin_init();
+}
+

test/dub_package/frontend.d

@@ -0,0 +1,121 @@
+#!/usr/bin/env dub
+/+dub.sdl:
+dependency "dmd" path="../.."
++/
+import std.stdio;
+
+// add import paths
+void addImports(T)(T path)
+{
+    import ddmd.globals : global;
+    import ddmd.arraytypes : Strings;
+
+    Strings* res = new Strings();
+    foreach (p; path)
+    {
+        import std.string : toStringz;
+        Strings* a = new Strings();
+        a.push(p.toStringz);
+        res.append(a);
+    }
+    global.path = res;
+}
+
+// finds a dmd.conf and parses it for import paths
+auto findImportPaths()
+{
+    import std.string : fromStringz, toStringz;
+    import std.path : buildPath, buildNormalizedPath, dirName;
+    import std.process : env = environment;
+    import ddmd.dinifile : findConfFile;
+
+    auto dmdFilePath = env.get("DMD");
+    auto iniFile = findConfFile(dmdFilePath.toStringz, "dmd.conf");
+
+    import std.algorithm, std.range, std.regex;
+    return File(iniFile.fromStringz, "r")
+        .byLineCopy
+        .dropOne
+        .front
+        .matchAll("-I[^ ]+".regex)
+        .joiner
+        .map!(a => a.drop(2).replace("%@P%", dmdFilePath.dirName))
+        .map!buildNormalizedPath;
+}
+
+// test frontend
+void main()
+{
+    import ddmd.astcodegen : ASTCodegen;
+    import ddmd.dmodule : Module;
+    import ddmd.globals : global, Loc;
+    import ddmd.frontend : initDMD;
+    import ddmd.parse : Parser;
+    import ddmd.statement : Identifier;
+    import ddmd.tokens : TOKeof;
+    import ddmd.id : Id;
+    import ddmd.globals : global;
+
+    global._init;
+    global.params.isLinux = 1;
+    initDMD;
+    findImportPaths.addImports;
+
+    auto parse(Module m, string code) {
+        scope p = new Parser!ASTCodegen(m, code, false);
+        p.nextToken; // skip the initial token
+        auto members = p.parseModule;
+        assert(!p.errors, "Parsing error occurred.");
+        return members;
+    }
+
+    Identifier id = Identifier.idPool("test");
+    auto m = new Module("test.d", id, 0, 0);
+    m.members = parse(m, q{
+        void foo() {
+            foreach (i; 0..10) {
+            }
+        }
+    });
+
+    void semantic() {
+        import ddmd.dsymbolsem : dsymbolSemantic;
+        import ddmd.semantic : semantic2, semantic3;
+
+        m.importedFrom = m;
+        m.importAll(null);
+        m.dsymbolSemantic(null);
+        m.semantic2(null);
+        m.semantic3(null);
+    }
+    semantic();
+
+    auto prettyPrint() {
+        import ddmd.root.outbuffer: OutBuffer;
+        import ddmd.hdrgen : HdrGenState, PrettyPrintVisitor;
+
+        OutBuffer buf = { doindent: 1 };
+        HdrGenState hgs = { fullDump: 1 };
+        scope PrettyPrintVisitor ppv = new PrettyPrintVisitor(&buf, &hgs);
+        m.accept(ppv);
+        return buf;
+    }
+    auto buf = prettyPrint();
+
+    auto expected =q{import object;
+void foo()
+{
+    {
+        int __key3 = 0;
+        int __limit4 = 10;
+        for (; __key3 < __limit4; __key3 += 1)
+        {
+            int i = __key3;
+        }
+    }
+}
+};
+    import std.string : replace, fromStringz;
+    auto generated = buf.extractData.fromStringz.replace("\t", "    ");
+    assert(expected == generated, generated);
+}