ee321_termProject_v2.0.ino

#include <LiquidCrystal.h>
#include <Keypad.h>      

//COMPONENT SETUP

//1. Keypad Setup
const byte rows = 4; 
const byte columns = 3;
char keys[rows][columns] = {
  {'1','2','3'},
  {'4','5','6'},
  {'7','8','9'},
  {'*','0','#'}
};
const byte rowPins[rows] = {9, 8, 7, 6}; 
const byte colPins[columns] = {5, 4, 3}; 

//2. LCD Setup
const int rs = A0, en = A1, d4 = A2, d5 = A3, d6 = A4, d7 = A5;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

//3. Motor Setup
const int motorA_P1 = 13; 
const int motorA_P2 = 12; 
const int motorB_P1 = 11; 
const int motorB_P2 = 10;

//4. Emergency LED Setup
const int emergencyLed = 2;

enum SystemState {
  WELCOME,
  MAIN_MENU,
  GOTO_SIDE_A,
  GOTO_SIDE_B,
  CHANGE_MASTER,
  REPORT,
  MASTER_LOCK,
  TIME_LOCK
};

//GLOBAL VARIABLES

//1. System State Storage
SystemState currentState;
bool firstEntry = true;
String enteredDigits = "";
int passChangeStep  = 0;   
char passChangeOption  = ' '; 

//2. Keypad Initialization
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, rows, columns);

//3. Passwords
String masterPassword = "1234";
String sideAPassword  = "2222";
String sideBPassword  = "3333";
String baitPassword   = "9999";

//4. Attempt Counters
volatile int sfaCount = 0;
volatile int sfaSeconds = 0;
volatile bool sfaCleared = false;
int totalSuccessfulAttempts = 0;
int totalUnsuccessfulAttempts = 0;

//5. Timers
unsigned long timeLockStartTime = 0;

//6. Flags
bool sideA_isOpen = true; 
bool sideB_isOpen = true;

void handleWelcome();
void handleMainMenu();
void handleGoToSideA();
void handleGoToSideB();
void handleChangeMaster();
void handleReport();
void handleMasterLock();
void handleTimeLock();

void displayLCD(const String &line1, const String &line2, unsigned long delayMs = 0);
void blinkEmergency();
void operateSection(String section, bool open);
bool processPinEntry(const String &prompt);


void setup() {
  //LCD Setup
  lcd.begin(16,2);
  //Motor Setup
  pinMode(motorA_P1, OUTPUT);
  pinMode(motorA_P2, OUTPUT);
  pinMode(motorB_P1, OUTPUT);
  pinMode(motorB_P2, OUTPUT);
  pinMode(emergencyLed, OUTPUT);
  digitalWrite(motorA_P1, LOW);
  digitalWrite(motorA_P2, LOW);
  digitalWrite(motorB_P1, LOW);
  digitalWrite(motorB_P2, LOW);
  digitalWrite(emergencyLed, LOW);
  //Interrupt Setup
  noInterrupts();
  TCCR1A = 0;                
  TCCR1B = 0;
  TCNT1  = 0;                
  OCR1A  = 15624;            
  TCCR1B |= (1 << WGM12);    
  TCCR1B |= (1 << CS12) | (1 << CS10);  
  TIMSK1 |= (1 << OCIE1A);   
  interrupts();              
  //Initialisations
  currentState = WELCOME;
  firstEntry = true;
}

void loop() {
  switch(currentState) {
    case WELCOME:       handleWelcome();      break;
    case MAIN_MENU:     handleMainMenu();     break;
    case GOTO_SIDE_A:   handleGoToSideA();    break;
    case GOTO_SIDE_B:   handleGoToSideB();    break;
    case CHANGE_MASTER: handleChangeMaster(); break;
    case REPORT:        handleReport();       break;
    case MASTER_LOCK:   handleMasterLock();   break;
    case TIME_LOCK:     handleTimeLock();     break;
  }
}

void handleWelcome() {
  displayLCD(" Welcome to", "  Hotel Safe", 2000);
  currentState = MAIN_MENU;
  firstEntry = true;
}
void handleMainMenu() {
  if (firstEntry) {
    displayLCD("1:A  2:B  3:CP", "4:Report");
    firstEntry = false;
  }
  char k = keypad.getKey();
  if (!k) return;
  switch (k) {
    case '1': currentState = GOTO_SIDE_A;   break;
    case '2': currentState = GOTO_SIDE_B;   break;
    case '3': currentState = CHANGE_MASTER; break;
    case '4': currentState = REPORT;        break;
    default:  return; 
  }
  firstEntry = true;
}
void handleGoToSideA() {
  if (firstEntry) {
    enteredDigits = "";
    displayLCD("Enter Pass. A", "____");
    firstEntry = false;
  }
  if (!processPinEntry("Enter Pass. A")) {
    return;
  }

  String passcode = enteredDigits;
  enteredDigits = "";

  bool isValid = false;
  if (passcode == masterPassword || passcode == sideAPassword) {
    isValid = true;
  } else if (passcode == baitPassword) {
    isValid = true;
    blinkEmergency();
  }

  if (isValid) {
    totalSuccessfulAttempts++;
    sfaCount   = 0;
    sfaSeconds = 0;
    operateSection("A", !sideA_isOpen);
    currentState = MAIN_MENU;
  } else {
    totalUnsuccessfulAttempts++;
    sfaCount++;
    sfaSeconds = 0;
    displayLCD("Wrong Password!", "", 2000);
    currentState = (sfaCount < 3 ? GOTO_SIDE_A : MASTER_LOCK);
  }
  firstEntry = true;
}
void handleGoToSideB() {
  if (firstEntry) {
    enteredDigits = "";
    displayLCD("Enter Pass. B", "____");
    firstEntry = false;
  }
  if (!processPinEntry("Enter Pass. B")) {
    return;  
  }
  String passcode = enteredDigits;
  enteredDigits = "";    

  bool isValid = false;
  if (passcode == masterPassword || passcode == sideBPassword) {
    isValid = true;
  } else if (passcode == baitPassword) {
    isValid = true;
    blinkEmergency();
  }

  if (isValid) {
    totalSuccessfulAttempts++;
    sfaCount   = 0;
    sfaSeconds = 0;
    operateSection("B", !sideB_isOpen);
    currentState = MAIN_MENU;
  } 
  else {
    totalUnsuccessfulAttempts++;
    sfaCount++;
    sfaSeconds = 0;
    displayLCD("Wrong Password!", "", 2000);
    currentState = (sfaCount < 3 ? GOTO_SIDE_B : MASTER_LOCK);
  }
  firstEntry = true;
}
void handleChangeMaster() {
  switch (passChangeStep) {
    // verify current master password
    case 0: {
      if (firstEntry) {
        enteredDigits = "";
        displayLCD("Master P. for CP", "____");
        firstEntry = false;
      }
      if (!processPinEntry("Master P. for CP")) return;

      {
        String passcode = enteredDigits;
        enteredDigits = "";
        if (passcode == masterPassword) {
          passChangeStep = 1;
        } else {
          totalUnsuccessfulAttempts++;
          sfaCount++;
          sfaSeconds = 0;
          displayLCD("Wrong Password", "", 1000);
          if (sfaCount >= 3) {
            currentState = MASTER_LOCK;
            passChangeStep = 0;
          }
        }
        firstEntry = true;
      }
      break;
    }

    // pick which password to change
    case 1: {
      if (firstEntry) {
        displayLCD("CP 1M 2A 3B 4T", "");
        firstEntry = false;
      }
      char k = keypad.getKey();
      if (!k) return;
      if (strchr("1234", k)) {
        passChangeOption = k;
        passChangeStep   = 2;
        firstEntry = true;
      }
      break;
    }

    // enter the new password
    case 2: {
      if (firstEntry) {
        String prompt = "Enter New Pass. ";
        switch (passChangeOption) {
          case '1': prompt += "M"; break;
          case '2': prompt += "A"; break;
          case '3': prompt += "B"; break;
          case '4': prompt += "T"; break;
        }
        enteredDigits = "";
        displayLCD(prompt, "____");
        firstEntry = false;
      }
      if (!processPinEntry(String("Enter New Pass. ") + passChangeOption)) return;
      {
        String newPassword = enteredDigits;
        enteredDigits = "";
        switch (passChangeOption) {
          case '1': masterPassword = newPassword; break;
          case '2': sideAPassword  = newPassword; break;
          case '3': sideBPassword  = newPassword; break;
          case '4': baitPassword   = newPassword; break;
        }
        displayLCD("Pass is changed", "", 1000);
        passChangeStep = 0;
        currentState   = MAIN_MENU;
        firstEntry     = true;
      }
      break;
    }
  }
}
void handleReport() {
  if (firstEntry) {
    displayLCD("Success : " + String(totalSuccessfulAttempts),
               "Failure : " + String(totalUnsuccessfulAttempts),
               3000); 
    firstEntry = false;
  }
  currentState = MAIN_MENU;
  firstEntry   = true;
}
void handleMasterLock() {
  if (firstEntry) {
    enteredDigits = "";
    displayLCD("System Locked MP", "____");
    firstEntry = false;
  }
  if (!processPinEntry("System Locked MP")) {
    return;
  }

  String code = enteredDigits;
  enteredDigits = "";    

  if (code == masterPassword) {
    sfaCount   = 0;
    sfaSeconds = 0;
    currentState = MAIN_MENU;
  } else {
    currentState = TIME_LOCK;
  }
  firstEntry = true;
}
void handleTimeLock() {
  static int lastRemaining = -1;

  if (firstEntry) {
    timeLockStartTime = millis();
    lastRemaining = -1;
    firstEntry = false;
  }

  unsigned long elapsedSec = (millis() - timeLockStartTime) / 1000;
  int remaining = 20 - elapsedSec;

  if (remaining >= 0 && remaining != lastRemaining) {
    displayLCD("No access for", String(remaining) + " sec");
    lastRemaining = remaining;
  }

  if (elapsedSec >= 20) {
    currentState = MASTER_LOCK;
    firstEntry   = true;
  }
}

void displayLCD(const String &line1, const String &line2, unsigned long delayMs = 0) {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print(line1);
  lcd.setCursor(0,1);
  lcd.print(line2);
  if (delayMs) {
    delay(delayMs);
  }
}
void blinkEmergency() {
  digitalWrite(emergencyLed, HIGH);
  delay(1000);
  digitalWrite(emergencyLed, LOW);
}
void operateSection(String section, bool open) {
  int pin1 = (section == "A" ? motorA_P1 : motorB_P1);
  int pin2 = (section == "A" ? motorA_P2 : motorB_P2);
  bool &isOpenFlag = (section == "A" ? sideA_isOpen : sideB_isOpen);
  String label = (section == "A" ? "Sect A" : "Sect B");
  
  displayLCD(label + (open ? " opening" : " locking"), "", 2000);
  if (open) {
    digitalWrite(pin1, HIGH);
    digitalWrite(pin2, LOW);
  } else {
    digitalWrite(pin1, LOW);
    digitalWrite(pin2, HIGH);
  }
  delay(1850);
  digitalWrite(pin1, LOW);
  digitalWrite(pin2, LOW);

  isOpenFlag = open;
}
bool processPinEntry(const String &prompt) {
  char k = keypad.getKey();
  if (!k) return false;
  if (isdigit(k)) {
    enteredDigits += k;
    String mask;
    for (int i = 0; i < 4; i++) {
      mask += (i < enteredDigits.length() ? '*' : '_');
    }
    displayLCD(prompt, mask);
  }
  return (enteredDigits.length() == 4);
}
ISR(TIMER1_COMPA_vect) {
  if (sfaCount > 0) {
    if (++sfaSeconds >= 15) {
      sfaCount   = 0;   
      sfaSeconds = 0;
      sfaCleared = true;
    }
  }
}