wfetch/flake.nix at main · iynaix/wfetch · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    systems.url = "github:nix-systems/default";
  };

  outputs =
    inputs@{
      flake-parts,
      nixpkgs,
      self,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = import inputs.systems;

      perSystem =
        { pkgs, ... }:
        let
          ascii-image-converter' = pkgs.ascii-image-converter.overrideAttrs (old: {
            postPatch = ''
              substituteInPlace aic_package/util.go \
                --replace-fail "saveAscii := flattenAscii(asciiSet, false, true)" \
                "saveAscii := flattenAscii(asciiSet, true, false)"
            '';
          });
        in
        {
          devShells = {
            default = pkgs.mkShell {
              packages = with pkgs; [
                cargo-edit
                fastfetch
                ascii-image-converter'
              ];

              env = {
                # Required by rust-analyzer
                RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
              };

              nativeBuildInputs = with pkgs; [
                cargo
                rustc
                rust-analyzer
                rustfmt
                clippy
                pkg-config
              ];

              buildInputs = with pkgs; [
                glib
                gexiv2 # for reading metadata
              ];
            };
          };

          packages = rec {
            wfetch = pkgs.callPackage ./package.nix {
              version =
                if self ? "shortRev" then
                  self.shortRev
                else
                  nixpkgs.lib.replaceStrings [ "-dirty" ] [ "" ] self.dirtyShortRev;
              # patched version of ascii-image-converter
              ascii-image-converter = ascii-image-converter';
            };
            ascii-image-converter = ascii-image-converter';
            default = wfetch;
          };
        };
      flake = {
        hydraJobs = {
          inherit (self) devShells packages;
        };
      };
    };
}