stabil-api/shell.nix at main · jmir1/stabil-api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
{
  pkgs ? import <nixpkgs> { },
}:
let
  yaz = pkgs.stdenv.mkDerivation rec {
    pname = "yaz";
    version = "5.37.0";

    src = pkgs.fetchurl {
      url = "https://download.indexdata.com/pub/yaz/yaz-${version}.tar.gz";
      sha256 = "sha256-klf+sG4v27/Ot9BAwTn6E5V8TR67pqopOm3RPKsiJc4=";
    };

    nativeBuildInputs = with pkgs; [
      automake
      autoconf
      libtool
      pkg-config
    ];

    buildInputs = with pkgs; [
      libxml2
      libxslt
      icu
      readline
    ];

    configureFlags = [
      "--enable-shared"
      "--with-xml2"
      "--with-xslt"
      "--with-icu"
    ];

    meta = with pkgs.lib; {
      description = "Z39.50/SRU/Solr client and server";
      homepage = "https://www.indexdata.com/resources/software/yaz/";
      license = licenses.bsd3;
    };
  };
in
pkgs.mkShell {
  buildInputs = with pkgs; [
    rustc
    cargo
    clippy
    rustfmt
    openssl
    pkg-config
    rust-analyzer
    clang

    # yaz toolkit as defined above
    yaz
    libxslt
    libxml2
  ];
  LIBCLANG_PATH = pkgs.lib.makeLibraryPath [ pkgs.llvmPackages_latest.libclang.lib ];
  RUST_SRC_PATH = "${pkgs.rust.packages.stable.rustPlatform.rustLibSrc}";
}