UClaseForeignKey.pas

unit UClaseForeignKey;

interface // CLASE PARA MANEJAR LA CREACION DE UN CONSTRAINT DE TIPO FOREIGN KEY

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.Menus, Vcl.StdCtrls, Vcl.ExtCtrls;


type
  // Enumerados para acciones de integridad referencial
  TAccionReferencial = (arNoAction, arCascade, arSetNull, arSetDefault);

  TForeignKey = class
  private
    FNombre        : string;
    FTablaOrigen   : string;
    FCamposOrigen  : TStringList;
    FTablaDestino  : string;
    FCamposDestino : TStringList;
    FAccionUpdate  : TAccionReferencial;
    FAccionDelete  : TAccionReferencial;
    FDescripcion   : string;
  public
    constructor Create;
    destructor Destroy; override;

    property Nombre : string read FNombre write FNombre;
    property TablaOrigen : string read FTablaOrigen write FTablaOrigen;
    property CamposOrigen : TStringList read FCamposOrigen;
    property TablaDestino : string read FTablaDestino write FTablaDestino;
    property CamposDestino : TStringList read FCamposDestino;
    property AccionUpdate : TAccionReferencial read FAccionUpdate write FAccionUpdate;
    property AccionDelete : TAccionReferencial read FAccionDelete write FAccionDelete;
    property Descripcion : string read FDescripcion write FDescripcion;

    function GenerarScriptCreacion : string;
    function GenerarScriptEliminacion : string;
  end;


implementation


// Implementación del constructor de TForeignKey
constructor TForeignKey.Create;
begin
  inherited;
  FCamposOrigen  := TStringList.Create;
  FCamposDestino := TStringList.Create;
  FAccionUpdate  := arNoAction;
  FAccionDelete  := arNoAction;
end;

destructor TForeignKey.Destroy;
begin
  FCamposOrigen.Free;
  FCamposDestino.Free;
  inherited;
end;

function TForeignKey.GenerarScriptCreacion : string;
var
  SB : TStringBuilder;
  I  : Integer;
  CamposOrigenStr, CamposDestinoStr, AccionUpdateStr, AccionDeleteStr : string;
begin
  SB := TStringBuilder.Create;
  try
    // Comentario descriptivo
    if FDescripcion <> '' then
    begin
      SB.AppendLine('/* ');
      SB.AppendLine(FDescripcion);
      SB.AppendLine('*/');
      SB.AppendLine;
    end;

    // Encabezado ALTER TABLE
    SB.AppendLine('ALTER TABLE ' + FTablaOrigen);
    SB.Append('ADD CONSTRAINT ' + FNombre + ' FOREIGN KEY');

    // Campos origen
    SB.Append(' (');
    CamposOrigenStr := '';

    for I := 0 to FCamposOrigen.Count - 1 do
    begin
      if I > 0 then
        CamposOrigenStr := CamposOrigenStr + ', ';

      CamposOrigenStr := CamposOrigenStr + FCamposOrigen[I];
    end;

    SB.Append(CamposOrigenStr + ')');

    // Referencias a tabla destino
    SB.AppendLine();
    SB.Append('REFERENCES ' + FTablaDestino + ' (');

    CamposDestinoStr := '';
    for I := 0 to FCamposDestino.Count - 1 do
    begin
      if I > 0 then
        CamposDestinoStr := CamposDestinoStr + ', ';

      CamposDestinoStr := CamposDestinoStr + FCamposDestino[I];
    end;

    SB.Append(CamposDestinoStr + ')');

    // Acciones referenciales
    case FAccionUpdate of
      arNoAction: AccionUpdateStr := 'NO ACTION';
      arCascade: AccionUpdateStr := 'CASCADE';
      arSetNull: AccionUpdateStr := 'SET NULL';
      arSetDefault: AccionUpdateStr := 'SET DEFAULT';
    end;

    case FAccionDelete of
      arNoAction: AccionDeleteStr := 'NO ACTION';
      arCascade: AccionDeleteStr := 'CASCADE';
      arSetNull: AccionDeleteStr := 'SET NULL';
      arSetDefault: AccionDeleteStr := 'SET DEFAULT';
    end;

    SB.AppendLine();
    SB.Append('ON UPDATE ' + AccionUpdateStr);
    SB.AppendLine();
    SB.Append('ON DELETE ' + AccionDeleteStr);

    SB.AppendLine();
    SB.Append('GO');

    Result := SB.ToString;
  finally
    SB.Free;
  end;
end;

function TForeignKey.GenerarScriptEliminacion : string;
var
  SB : TStringBuilder;
begin
  SB := TStringBuilder.Create;
  try
    SB.AppendLine('IF EXISTS (SELECT * FROM sys.foreign_keys WHERE object_id = OBJECT_ID(N''' +
                FNombre + ''') AND parent_object_id = OBJECT_ID(N''' + FTablaOrigen + '''))');
    SB.AppendLine('  ALTER TABLE ' + FTablaOrigen);
    SB.AppendLine('  DROP CONSTRAINT ' + FNombre + ';');
    SB.AppendLine('GO');

    Result := SB.ToString;
  finally
    SB.Free;
  end;
end;




end.