nvim/flake.nix at master · k3dom/nvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
{
  description = "A nixvim configuration";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    nixvim = {
      url = "github:nix-community/nixvim";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    neovim-nightly = {
      url = "github:nix-community/neovim-nightly-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = {nixpkgs, ...} @ inputs: let
    useNightly = false;
    eachSupportedSystem = f:
      nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed (system:
        f {
          inherit system;
          pkgs = import nixpkgs {
            inherit system;
            overlays = nixpkgs.lib.optionals useNightly [
              inputs.neovim-nightly.overlays.default
            ];
          };
        });
    nixvimModule = pkgs: {
      inherit pkgs;
      module = ./config;
      extraSpecialArgs = {
        inherit inputs;
      };
    };
  in {
    packages = eachSupportedSystem ({
      pkgs,
      system,
    }: {
      default = inputs.nixvim.legacyPackages.${system}.makeNixvimWithModule (nixvimModule pkgs);
    });
    checks = eachSupportedSystem ({
      pkgs,
      system,
    }: {
      default = inputs.nixvim.lib.${system}.check.mkTestDerivationFromNixvimModule (nixvimModule pkgs);
    });
    devShells = eachSupportedSystem ({pkgs, ...}: {
      default = pkgs.mkShell {
        packages = with pkgs; [
          statix
        ];
      };
    });
    formatter = eachSupportedSystem ({pkgs, ...}: pkgs.alejandra);
  };
}