sample_insitu/sample.ncl at master · kaizhangpnl/sample_insitu · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185

;;  model history file

    fna = "example_monthly_2D.nc"
    fna = "example_monthly_3D.nc"

;;  site location information

    fnb = "latlon.nc"

;;  output file

    fno = "OUT_" + fna

    system("rm " + fno)

;;...........................................................
;;  load data
;;...........................................................

    fla = addfile(fna, "r")
    flb = addfile(fnb, "r")
    flo = addfile(fno, "c")

    lat = flb->lat
    lon = flb->lon

    ns = dimsizes(lat) ; number of stations

    vn = getfilevarnames(fla)  ; get names of all variables on file

    nv = dimsizes (vn)   ; number of variables on the file

    time = fla->time

;;...........................................................
;;  determine if we have levels
;;...........................................................
    have_levels = isfilevar(fla,"lev")

    if(have_levels) then
       hyam = fla->hyam
       hybm = fla->hybm
       hyai = fla->hyai
       hybi = fla->hybi
    end if

;;...........................................................
;;  loop over variables
;;...........................................................

    do n=0,nv-1

       vv = fla->$vn(n)$        ; read the varible to memory

       ndim = dimsizes(vv)        ; dimension size of the variable
       nran = dimsizes(ndim)      ; rank [ie: number of dimensions]

       bname = vn(n)
       wn    = bname

;;...........................................................
;;     3-D
;;...........................................................

       if(nran.eq.3) then
          va = vv
          n1 = dimsizes(va(:,0,0))
          n2 = dimsizes(va(0,:,0))
          n3 = dimsizes(va(0,0,:))

          wn = bname

          wa = new((/n1,ns/),"float")

          wa!1 = "st"
          wa&st = ispan(1,ns,1)
          wa&st@long_name = "station"

          wa!0 = "time"
          wa&time = time

          wa@long_name = va@long_name
          wa@units     = va@units

          ;; get grid-box mean value

          do is = 0, ns-1
             wa(:,is) = (/ va(:,{lat(is)},{lon(is)}) /)
          end do

          print(" varname : " + wn )               ; print all variable names on file
          flo->$wn$=wa

          delete(va)
          delete(wa)

       end if

;;...........................................................
;;     4-D
;;...........................................................

       if(nran.eq.4) then

          va = vv

          n1 = dimsizes(va(:,0,0,0))
          n2 = dimsizes(va(0,:,0,0))
          n3 = dimsizes(va(0,0,:,0))
          n4 = dimsizes(va(0,0,0,:))

          bname = vn(n)

          wn = bname

          wa = new((/n1,n2,ns/),"float")

          wa!2 = "st"
          wa&st = ispan(1,ns,1)
          wa&st@long_name = "station"

          wa!0 = "time"
          wa&time = time

          wa!1 = "lev"
          wa&lev = va&lev

          wa@long_name = va@long_name
          wa@units     = va@units

          ;; get grid-box mean value

          do is = 0, ns-1
             wa(:,:,is) = (/ va(:,:,{lat(is)},{lon(is)}) /)
          end do

          print(" varname : " + wn )               ; print all variable names on file
          flo->$wn$=wa

          delete(va)
          delete(wa)

       end if

       ;;print(" varname : " + wn )               ; print all variable names on file

       delete(ndim)
       delete(vv)

   end do


;;........................................................................................
;; Coordinate info
;;........................................................................................
   if(have_levels) then
      flo->hyam=hyam
      flo->hybm=hybm
      flo->hyai=hyai
      flo->hybi=hybi
   end if

   stname = asciiread("st.dat",-1,"string")

   wallClock = systemfunc("date")

;;........................................................................................
;; file provenance
;;........................................................................................

   fatt                          = True
   fatt@experiment               = "INSITU"
   fatt@source                   = "https://wiki.met.no/_media/aerocom/INSITU_Station_Inventory.xlsx"
   fatt@creat_time               = wallClock

   fatt@station_name = ""

   do is = ns-1,0,1
      it = is + 1
      myname = "station_name_" + it
      fatt@$myname$         = stname(is)
   end do

   fileattdef( flo, fatt )