release/flake.nix at main · meigma/release · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
{
  description = "Meigma release-cli";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";

  outputs =
    { self, nixpkgs, ... }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
      forAllSystems = nixpkgs.lib.genAttrs systems;
      version = (builtins.fromJSON (builtins.readFile ./.release-please-manifest.json)).".";
      commit =
        if self ? rev then
          self.rev
        else if self ? dirtyRev then
          self.dirtyRev
        else
          "unknown";
      packageFor =
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          go = pkgs.go_1_26.overrideAttrs {
            version = "1.26.6";
            src = pkgs.fetchurl {
              url = "https://go.dev/dl/go1.26.6.src.tar.gz";
              hash = "sha256-oHIcVMaIkBRI13rZs+x+p8R0cwdV/4kTgukuy5P/LLE=";
            };
          };
          buildGoModule = pkgs.buildGoModule.override { inherit go; };
        in
        buildGoModule {
          pname = "release-cli";
          inherit version;
          src = self;
          vendorHash = "sha256-6qxVn5Tl6J5NMIGuEN4c51J/r7f9td/eTEh2qbW6qa8=";
          subPackages = [ "cmd/release-cli" ];
          env.CGO_ENABLED = "0";
          ldflags = [
            "-s"
            "-w"
            "-X=main.version=${version}"
            "-X=main.commit=${commit}"
          ];
          meta = {
            description = "Validate and publish Meigma release artifacts";
            homepage = "https://github.com/meigma/release";
            license = with pkgs.lib.licenses; [ asl20 mit ];
            mainProgram = "release-cli";
            platforms = systems;
          };
        };
    in
    {
      packages = forAllSystems (
        system:
        let
          package = packageFor system;
        in
        {
          release-cli = package;
          default = package;
        }
      );

      apps = forAllSystems (
        system:
        let
          app = {
            type = "app";
            program = "${self.packages.${system}.release-cli}/bin/release-cli";
            meta.description = "Run release-cli";
          };
        in
        {
          release-cli = app;
          default = app;
        }
      );

      checks = forAllSystems (system: {
        release-cli = self.packages.${system}.release-cli;
      });
    };
}