Justfile

set dotenv-load := false

# List available recipes
default:
    @just --list

# Run all quality checks: linting, tests, and coverage threshold
qa: lint test-coverage-gate

# Run all linters in parallel
lint:
    @echo -n 'cs-fixer phpstan rector' | parallel --will-cite --halt now,fail=1 --delimiter=' ' just lint-{}

# Check code style (PSR-12)
lint-cs-fixer:
    php-cs-fixer fix --diff --verbose --dry-run

# Run static analysis
lint-phpstan:
    phpstan analyse

# Check for Rector refactoring opportunities
lint-rector:
    rector --dry-run

# Auto-fix code style
format:
    php-cs-fixer fix --diff --verbose

# Apply Rector refactorings
format-rector:
    rector

# Run tests
test:
    phpunit

# Run tests with coverage report
test-coverage:
    phpunit --coverage-text --coverage-html=var/coverage

# Run tests with coverage and fail if line coverage is below threshold
[private]
test-coverage-gate:
    #!/usr/bin/env bash
    set -euo pipefail
    threshold=85
    output=$(phpunit --coverage-text --coverage-clover=var/coverage.xml 2>&1)
    echo "$output"
    # Extract the "Lines:" percentage from coverage summary
    coverage=$(echo "$output" | grep -oP 'Lines:\s+\K[0-9]+(?:\.[0-9]+)?' | head -1)
    if [ -z "$coverage" ]; then
        echo "ERROR: Could not parse line coverage from PHPUnit output."
        exit 1
    fi
    # Compare using bc for float comparison
    below=$(echo "$coverage < $threshold" | bc -l)
    if [ "$below" -eq 1 ]; then
        echo ""
        echo "FAILED: Line coverage ${coverage}% is below the ${threshold}% threshold."
        exit 1
    fi
    echo ""
    echo "OK: Line coverage ${coverage}% meets the ${threshold}% threshold."

# Generate API documentation
docs:
    docker run --rm --user "$(id -u):$(id -g)" -v $(pwd):/data phpdoc/phpdoc:3 run --setting="guides.enabled=true"

# Download fresh W3C spec files
update-specs:
    php bin/update-specs.php

# Run code generation from W3C specs
generate: update-specs
    php bin/generate.php