dora/android_test_coverage.gradle at master · nrudenko/dora · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
apply plugin: 'jacoco'

project.android {
    Task allVariantsTask = tasks.create(
            name: 'jacocoTestReport',
            type: DefaultTask,
            dependsOn: 'test') {
        group = "Reporting"
        description = "Generate Jacoco coverage reports"
    }

    if (hasProperty('libraryVariants')) {
        libraryVariants.all { variant ->
            def reportTask = createReportTask(variant)
            tasks.add(reportTask)
            allVariantsTask.dependsOn(reportTask)
        }
    }
    if (hasProperty('applicationVariants')) {
        applicationVariants.all { variant ->
            def reportTask = createReportTask(variant)
            tasks.add(reportTask)
            allVariantsTask.dependsOn(reportTask)
        }
    }
}

def createReportTask(buildVariant) {
    String testTaskName = "test${buildVariant.name.capitalize()}UnitTest"
    String reportTaskName = "jacocoTestReport${buildVariant.name.capitalize()}"
    Task task = task(
            name: reportTaskName,
            type: JacocoReport,
            dependsOn: "${testTaskName}") {
        group = "Reporting"
        description = "Generate Jacoco coverage reports for ${buildVariant.name}"

        classDirectories = fileTree(
                dir: "${project.buildDir}/intermediates/classes/${buildVariant.dirName}",
                excludes: ['**/R.class',
                           '**/R$*.class',
                           '**/*$ViewInjector*.*',
                           '**/BuildConfig.*',
                           '**/Manifest*.*',
                           '**/*_*Factory.*',
                           '**/*_Provide*Factory.*',
                           '**/*_MembersInjector.*',
                ]
        )

        sourceDirectories = files("src/main/java", "src/${buildVariant.variantData.variantConfiguration.getFlavorName()}/java")
        executionData = files("${project.buildDir}/jacoco/${testTaskName}.exec")

        reports {
            xml.enabled = true
            html.enabled = true
            html.destination "${buildDir}/jacocoHtml"
        }
    }
    return task
}