forge-server-jetty/build.gradle at main · ogrebgr/forge-server-jetty · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
plugins {
    id 'java-library'
    id 'org.jetbrains.kotlin.jvm' version '2.2.20'
    id "signing"
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
}

ext {
    forge_server_jetty_version = '24.0.0'
}

apply plugin: 'maven-publish'

group = 'com.bolyartech.forge.server'
version forge_server_jetty_version

repositories {
    mavenCentral()
//    mavenLocal()
}

ext.jettyVersion = '12.1.7'

dependencies {
//    api project(':forge-server')
    api 'com.bolyartech.forge.server:forge-server:24.0.0'
    api "org.eclipse.jetty.ee10:jetty-ee10-webapp:$jettyVersion"
    api "org.eclipse.jetty.ee10:jetty-ee10-servlet:$jettyVersion"
    api "org.eclipse.jetty.ee10:jetty-ee10-servlets:$jettyVersion"

    testImplementation 'org.jetbrains.kotlin:kotlin-test'
}

test {
    useJUnitPlatform()
}


tasks.withType(Javadoc).configureEach {
    enabled = false
}


tasks.register('javadocJar', Jar) {
    archiveClassifier = 'javadoc'
    from javadoc
}

tasks.register('sourcesJar', Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}


publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            groupId 'com.bolyartech.forge.server'
            artifactId 'forge-server-jetty'
            version forge_server_jetty_version
            artifact sourcesJar
            artifact javadocJar

            pom {
                name = 'Forge Server Jetty'
                packaging = 'jar'
                // optionally artifactId can be defined here
                description = 'Jetty implementation of Forge Server'
                url = 'https://github.com/ogrebgr/forge-server-jetty'

                scm {
                    connection = 'scm:git:https://github.com/ogrebgr/forge-server-jetty.git'
                    developerConnection = 'scm:git:https://github.com/ogrebgr/forge-server-jetty.git'
                    url = 'https://github.com/ogrebgr/forge-server-jetty'
                }

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id = 'ogremir'
                        name = 'Ognyan Bankov'
                        email = 'bankov@bolyartech.com'
                    }
                }
            }
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            stagingProfileId.set("com.bolyartech")
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            username = findProperty('ossrhUsername')
            password = findProperty('ossrhPassword')
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

kotlin {
    jvmToolchain(17)
}