jsolid/build.smooth at master · perunlabs/jsolid · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
#
# This is build script for jsolid library.
# You need smooth-build tool to use it.
# It can be downloaded for free from http://www.smoothbuild.org/
#

vecmath_jar            = file("lib/vecmath-1.3.1.jar");
hamcrest_core_jar      = file("lib/hamcrest-core-1.3.jar");
hamcrest_library_jar   = file("lib/hamcrest-library-1.3.jar");
junit_jar              = file("lib/junit-4.12.jar");
testory_jar            = file("lib/testory-1.4.0.jar");

sourceFiles = files("src/java");

dep_jars = [
  vecmath_jar,
];

jsolid_classes = javac(
    srcs = sourceFiles,
    libs = dep_jars,
    source = "1.8",
    target = "1.8",
);

jsolid_jar =
    concat([jsolid_classes, sourceFiles])
  > jarFile("jsolid.jar");

testing_jars = [
  junit_jar,
  hamcrest_core_jar,
  hamcrest_library_jar,
  jsolid_jar,
  testory_jar,
];

junit_dep_jars = concat([dep_jars, testing_jars]);

test_classes = javac(
  srcs = files("src/junit"),
  source = "1.8",
  target = "1.8",
  libs = junit_dep_jars,
);
test_jar = jarFile(test_classes, "test.jar");

test =
  junit(
    include = "**/*Test.class",
    tests = test_jar,
    deps = junit_dep_jars,
  );