llama_build_only.bat

@echo off
setlocal EnableExtensions

rem ==========================================================
rem  Llama.cpp Community Build Script (Windows 10/11)
rem  Checks prerequisites, installs if needed, and builds llama.cpp
rem  developed by SAmedia / py-sandy / Sandra Weidmann 
rem  license: GPLv3
rem ==========================================================

pushd "%~dp0"

set "VSPATH="
if exist "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" (
    for /f "usebackq tokens=*" %%i in (`
        "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" ^
            -latest -products * ^
            -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 ^
            -property installationPath
    `) do set "VSPATH=%%i"
)

echo [INFO] Visual Studio found at: %VSPATH%

rem --- trying first vcvars64.bat ---
if exist "%VSPATH%\VC\Auxiliary\Build\vcvars64.bat" (
    call "%VSPATH%\VC\Auxiliary\Build\vcvars64.bat" || goto :err
) else (
    rem --- then try VsDevCmd.bat ---
    if exist "%VSPATH%\Common7\Tools\VsDevCmd.bat" (
        call "%VSPATH%\Common7\Tools\VsDevCmd.bat" -arch=x64 -host_arch=x64 || goto :err
    ) else (
        echo [ERROR] Even vcvars64.bat nor VsDevCmd.bat was found!
        goto :err
    )
)

rem --- change to script folder ---
pushd "%~dp0" || goto :err

rem --- clone llama.cpp repo  ---
if not exist "llama.cpp\.git" (
    git clone https://github.com/ggml-org/llama.cpp.git || goto :err
)

rem --- change to llama.cpp ---
pushd "llama.cpp" || goto :err

rem --- prepare vcpkg ---
set "VCPKG_ROOT=%CD%\vcpkg"
if not exist "%VCPKG_ROOT%\." (
    git clone https://github.com/microsoft/vcpkg.git "%VCPKG_ROOT%" || goto :err
    call "%VCPKG_ROOT%\bootstrap-vcpkg.bat" || goto :err
)

"%VCPKG_ROOT%\vcpkg.exe" install curl:x64-windows || goto :err

set "BUILD_DIR=%CD%\build"
set "LOGFILE=%CD%\build_log.txt"

echo [BUILD] %DATE% %TIME% :: Configure + Build (Ninja) > "%LOGFILE%"
echo [INFO] CMake configure is starting ...
rem --- CMake Build ---
cmake -S . -B "%BUILD_DIR%" -G Ninja ^
  -DGGML_CUDA=ON ^
  -DGGML_CUDA_GRAPHS=ON ^
  -DGGML_CUDA_FA_ALL_QUANTS=ON ^
  -DLLAMA_CURL=ON ^
  -DCMAKE_CUDA_ARCHITECTURES=native ^
  -DCMAKE_BUILD_TYPE=Release ^
  -DCMAKE_TOOLCHAIN_FILE="%VCPKG_ROOT%\scripts\buildsystems\vcpkg.cmake" ^
  -DVCPKG_TARGET_TRIPLET=x64-windows ^
  -DCMAKE_CXX_FLAGS="/W0" >> "%LOGFILE%" 2>&1 || goto :err
  
echo [INFO] Build is starting...please wait...it can take some minutes... 

call :START_NINJA_PROGRESS "Build (Ninja)"

cmake --build "%BUILD_DIR%" -j %NUMBER_OF_PROCESSORS% >> "%LOGFILE%" 2>&1 || goto :err

rem --- finished ---
popd
popd
echo.
echo [INFO] Build done successfully!
echo [LOG] Details: "%LOGFILE%"
pause
exit /b 0

:err
echo.
echo [ERROR] Error at build or dependencies. See log: "%LOGFILE%"
pause
exit /b 1

:START_NINJA_PROGRESS
  setlocal EnableExtensions DisableDelayedExpansion

  set "___P_TITLE=%~1"
  if "%___P_TITLE%"=="" set "___P_TITLE=Ninja Build"

  rem Fallback if LOGFILE is not set.
  set "___P_LOG=%LOGFILE%"
  if not defined ___P_LOG set "___P_LOG=%CD%\build_log.txt"

  rem Handover to PowerShell via environment variables (reliable, no argument parsing).
  set "PS_NINJA_TITLE=%___P_TITLE%"
  set "PS_NINJA_LOG=%___P_LOG%"

  rem Background PowerShell: waits for ninja.exe, reads the log tail, shows % + bar on ONE line.
  start "" /b powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$ErrorActionPreference='SilentlyContinue';" ^
    "$title=$env:PS_NINJA_TITLE; $log=[Environment]::ExpandEnvironmentVariables($env:PS_NINJA_LOG);" ^
    "$reNinja=[regex]'^\s*\[(\d+)/(\d+)\]'; $reCMake=[regex]'^\s*\[\s*(\d{1,3})%\s*\]';" ^
    "$spin=@('|','/','-','\'); $i=0; $lastPct=$null; $done=$null; $total=$null;" ^
    "Write-Host '';" ^
    "$row=[Console]::CursorTop - 1;" ^
    "for($w=0; $w -lt 240 -and -not (Get-Process -Name 'ninja' -ErrorAction SilentlyContinue); $w++){ Start-Sleep -Milliseconds 250 }" ^
    "while(Get-Process -Name 'ninja' -ErrorAction SilentlyContinue){" ^
    "  $found=$false;" ^
    "  if (Test-Path $log){" ^
    "    try{ $tail = Get-Content -Path $log -Tail 1000 -ErrorAction Stop } catch { $tail=@() }" ^
    "    foreach($ln in $tail){" ^
    "      if($reNinja.IsMatch($ln)){" ^
    "        $m=$reNinja.Match($ln); $done=[int]$m.Groups[1].Value; $total=[int]$m.Groups[2].Value; if($total -gt 0){ $lastPct=[math]::Floor(100*$done/$total); $found=$true }" ^
    "      } elseif($reCMake.IsMatch($ln)){" ^
    "        $m=$reCMake.Match($ln); $lastPct=[int]$m.Groups[1].Value; $done=$null; $total=$null; $found=$true" ^
    "      }" ^
    "    }" ^
    "  }" ^
    "  $w=[Console]::WindowWidth;" ^
    "  if($w -lt 20){ $w=80 }" ^
    "  if($lastPct -ne $null){" ^
    "    $maxBar=[math]::Min(40,[math]::Max(10,$w-($title.Length+18))); " ^
    "    $fill=[math]::Floor($maxBar*$lastPct/100);" ^
    "    $bar=('#'*$fill).PadRight($maxBar,'-');" ^
    "    $ct= if($done -ne $null -and $total -ne $null) { '  ' + $done + '/' + $total } else { '' };" ^
    "    $txt='['+$lastPct+'%] '+$bar+$ct;" ^
    "  } else {" ^
    "    $txt='['+$spin[$i %% $spin.Length]+'] running...'; $i++" ^
    "  }" ^
    "  $line=$title+' '+$txt; if($line.Length -ge $w){ $line=$line.Substring(0,$w-1) }" ^
    "  [Console]::SetCursorPosition(0,$row);" ^
    "  [Console]::Write($line.PadRight($w-1));" ^
    "  [Console]::Title=$line;" ^
    "  Start-Sleep -Milliseconds 250" ^
    "}" ^
    "$w=[Console]::WindowWidth; if($w -lt 20){ $w=80 };" ^
    "$doneLine=$title+' [done]'; if($doneLine.Length -ge $w){ $doneLine=$doneLine.Substring(0,$w-1) };" ^
    "[Console]::SetCursorPosition(0,$row); [Console]::Write($doneLine.PadRight($w-1)); [Console]::Title=$title+' [done]';"

  endlocal & exit /b 0