ingest/Justfile at dev · realChakrawarti/ingest · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
set shell := ["cmd.exe", "/c"]

NODE_PM := "pnpm"
FIREBASE_START := "firebase --project ingest-dev emulators:start"
FIREBASE_EXPORT := "firebase --project ingest-dev emulators:export seed"

# list the available recipes
[default]
list:
    @just --list --unsorted

# check for any linter errors in the codebase
[group("Chore")]
lint level="":
    {{ NODE_PM }} oxlint {{ if level == "error" { "--quiet" } else { "" } }}

# format and fix all linter errors in the codebase
[group("Chore")]
format mode="":
    {{ NODE_PM }} oxfmt --{{ mode }}

# fix all formatting errors in the codebase
[group("Chore")]
format-on-save path:
    {{ NODE_PM }} oxfmt --stdin-filepath={{ path }}

# install all the project dependencies
[group("Chore")]
setup:
    {{ NODE_PM }} install

# remove .next directory, if exists
[group("Chore")]
clean:
    if not exist .next (@echo .next folder doesn't exists!) else (rmdir /s /q .next)

# build optimized production build
[group("Build")]
build: clean
    @echo Creating production build...
    {{ NODE_PM }} build

# build with output like rewrites, redirects, and headers
[group("Build")]
debug: clean
    {{ NODE_PM }} build --debug

# export firestore data
[group("Development")]
export-seed:
    {{ NODE_PM }} {{ FIREBASE_EXPORT }}

[private]
firebase-dev:
    {{ NODE_PM }} {{ FIREBASE_START }}

[private]
import-seed:
    {{ NODE_PM }} {{ FIREBASE_START }} --import=seed

[private]
next-dev:
    {{ NODE_PM }} dev

# starts the development server + firebase emulator
[group("Development")]
[parallel]
start: firebase-dev next-dev

# starts the development server + firebase emulator with seed data
[group("Development")]
[parallel]
start-seed: import-seed next-dev

# update the CONTRIBUTING.md with all the project dependencies metadata
[group("Chore")]
deps:
    pnpx dependex

# update the project to use the unified radix-ui mono package instead of individual @radix-ui/react-* packages
[group("Chore")]
ui-migrate:
    pnpx shadcn@latest migrate radix

# release <as>: patch|minor|major
[arg('as', pattern='patch|minor|release')]
[group("Build")]
release as:
    {{ NODE_PM }} release --release-as {{ as }}