nixconfiguration/flake.nix at master · rtanner1231/nixconfiguration · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
{
  description = "System Flake";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-sweep = {
      url = "github:jzbor/nix-sweep";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zen-browser.url = "github:0xc000022070/zen-browser-flake";
    sfdx = {
      url = "github:rfaulhaber/sfdx-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    suitecloud.url = "github:rtanner1231/suitecloud-nix";
    niri-flake = {
      url = "github:sodiboo/niri-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    noctalia = {
      url = "github:noctalia-dev/noctalia-shell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    wayscriber = {
      url = "github:devmobasa/wayscriber";
    };
    noctalia-calendar = {
      url = "path:/home/rick/projects/noctalia-calendar";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    apex-ls.url = "path:/home/rick/projects/apex_ls";
    # next-event = {
    #   url = "path:/home/rick/projects/qshell-next-event";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    # dms = {
    #   url = "github:AvengeMedia/DankMaterialShell/stable";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    # quickshell = {
    #   url = "git+https://git.outfoxxed.me/quickshell/quickshell";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
  };
  outputs =
    {
      self,
      nixpkgs,
      niri-flake,
      ...
    }@inputs:
    let
      wms = [
        { name = "gnome"; }
        { name = "cinnamon"; }
        { name = "kde"; }
        { name = "hyprland"; }
        {
          name = "niri";
          additionalModules = [ niri-flake.nixosModules.niri ];
        }
        { name = "cosmic"; }
      ];
      profiles = [
        {
          name = "l2";
          path = ./profiles/l2;
          user = "rick";
          git = {
            userName = "Richard Tanner";
            userEmail = "rtanner@myron.com";
          };
        }
        {
          name = "l1";
          path = ./profiles/l1;
          user = "rick";
          git = {
            userName = "Richard Tanner";
            userEmail = "rtanner@myron.com";
          };
        }
      ];
      system = "x86_64-linux";
      makeSystem =
        {
          profile,
          additionalModules ? [ ],
          wm,
        }:
        nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = {
            inherit wm inputs profile;
          };
          # Removed niri-flake from the base modules list
          modules = [
            profile.path
            inputs.nix-sweep.nixosModules.default
          ]
          ++ additionalModules;
        };
      allCombinations = nixpkgs.lib.concatMap (
        profile:
        builtins.map (wmObj: {
          name = "${profile.name}-${wmObj.name}";
          value = makeSystem {
            profile = profile;
            wm = wmObj.name;
            additionalModules = wmObj.additionalModules or [ ];
          };
        }) wms

      ) profiles;
    in
    {
      nixosConfigurations = nixpkgs.lib.listToAttrs allCombinations;
    };
}