CMakeLists.txt

# ##############################################################################
# CMakeLists.txt for the DiFfRG library
# ##############################################################################

cmake_minimum_required(VERSION 3.20)

project(FunKit LANGUAGES C)

set(CMAKE_INSTALL_MESSAGE LAZY)

include(${CMAKE_CURRENT_SOURCE_DIR}/utils/common.cmake)

if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.31.0")
  cmake_policy(SET CMP0177 NEW)
endif()

# ##############################################################################
# Install the Mathematica package
# ##############################################################################

find_program(WolframLanguage_wolframscript_EXE NAMES wolframscript wolfram math)

# See if the variable WolframLanguage_wolframscript_EXE is defined
if(DEFINED ENV{WOLFRAM_SCRIPT})
  set(WolframLanguage_wolframscript_EXE $ENV{WOLFRAM_SCRIPT})
elseif(NOT (WolframLanguage_wolframscript_EXE STREQUAL ""))
  # nothing to do, we found it with find_program
else()
  set(WolframLanguage_wolframscript_EXE "")
endif()

if(NOT DEFINED WolframLanguage_wolframscript_EXE
   OR WolframLanguage_wolframscript_EXE STREQUAL "")
  # download CPM.cmake
  file(
    DOWNLOAD
    https://github.com/cpm-cmake/CPM.cmake/releases/download/v0.40.8/CPM.cmake
    ${CMAKE_CURRENT_BINARY_DIR}/cmake/CPM.cmake
    EXPECTED_HASH
      SHA256=78ba32abdf798bc616bab7c73aac32a17bbd7b06ad9e26a6add69de8f3ae4791)
  include(${CMAKE_CURRENT_BINARY_DIR}/cmake/CPM.cmake)
  if("${CPM_SOURCE_CACHE}" STREQUAL "OFF" OR NOT DEFINED CPM_SOURCE_CACHE)
    if(WIN32)
      set(CPM_SOURCE_CACHE $ENV{LOCALAPPDATA}/CPM)
    else()
      set(CPM_SOURCE_CACHE $ENV{HOME}/.cache/CPM)
    endif()
  endif()
  # Get codeparser
  cpmaddpackage(
    NAME
    LibraryLinkUtilities
    GITHUB_REPOSITORY
    WolframResearch/LibraryLinkUtilities
    GIT_TAG
    v3.2.0
    DOWNLOAD_ONLY
    True)
  list(APPEND CMAKE_MODULE_PATH ${LibraryLinkUtilities_SOURCE_DIR}/cmake)

  find_package(WolframLanguage 12.0 COMPONENTS wolframscript)

  if(${WolframLanguage_FOUND})
    message(STATUS "Wolfram Language found: ${WolframLanguage_VERSION}")
  else()
    message(ERROR "Wolfram Language not found.")
  endif()
endif()

# strip newlines from the executable path. Happens sometimes, breaks everything
string(REPLACE "\n" "" WolframLanguage_wolframscript_EXE
               "${WolframLanguage_wolframscript_EXE}")
message(
  STATUS
    "Found a matching wolfram executable at: ${WolframLanguage_wolframscript_EXE}"
)

# get the application directory
execute_process(
  COMMAND ${WolframLanguage_wolframscript_EXE} -script
          ${CMAKE_CURRENT_SOURCE_DIR}/utils/get_wolfram_app_dir.m
  OUTPUT_VARIABLE WOLFRAM_APP_DIR
  OUTPUT_STRIP_TRAILING_WHITESPACE)
message(STATUS "Wolfram Language application directory: ${WOLFRAM_APP_DIR}")

# Install dependencies if we are NOT on windows
if(WIN32)
  execute_process(COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/dependencies/install.bat
                          ${WOLFRAM_APP_DIR})
else()
  execute_process(
    COMMAND bash ${CMAKE_CURRENT_SOURCE_DIR}/dependencies/install.sh
            ${WOLFRAM_APP_DIR})
endif()

# install the Mathematica package
install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/FunKit.m
        DESTINATION ${WOLFRAM_APP_DIR}/FunKit)
install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/PacletInfo.m
        DESTINATION ${WOLFRAM_APP_DIR}/FunKit)
install(
  DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/modules
            ${CMAKE_CURRENT_SOURCE_DIR}/examples
            ${CMAKE_CURRENT_SOURCE_DIR}/utils ${CMAKE_CURRENT_SOURCE_DIR}/tests
  MESSAGE_NEVER
  DESTINATION ${WOLFRAM_APP_DIR}/FunKit
  FILES_MATCHING
  PATTERN "*.m"
  PATTERN "*.wl"
  PATTERN "*.mx"
  PATTERN "*.nb")

# ##############################################################################
# Testing
# ##############################################################################

if(WIN32)
  add_custom_target(
    test
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m
    COMMENT "Running tests"
    VERBATIM)

  add_custom_target(
    test-single
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m $(FILE)
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m
    COMMENT "Running tests")
else()
  add_custom_target(
    test
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m | tee
      ${CMAKE_CURRENT_BINARY_DIR}/test.log
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m
    COMMENT "Running tests"
    VERBATIM)

  # Run a single test file or directory:
  #   make test-single FILE=FEDeriK/FunctionalDTests.m
  #   make test-single FILE=FEDeriK
  # Note: $(FILE) is expanded by Make at build time, not by CMake at configure
  # time. VERBATIM is intentionally omitted so that Make resolves the variable.
  add_custom_target(
    test-single
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m $(FILE) | tee
      ${CMAKE_CURRENT_BINARY_DIR}/test.log
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tests/Test.m
    COMMENT "Running tests")
endif()

# ##############################################################################
# Benchmarks
# ##############################################################################

if(WIN32)
  add_custom_target(
    bench
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m
    COMMENT "Running benchmarks"
    VERBATIM)

  add_custom_target(
    bench-single
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m $(FILE)
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m
    COMMENT "Running benchmark")
else()
  add_custom_target(
    bench
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m | tee
      ${CMAKE_CURRENT_BINARY_DIR}/bench.log
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m
    COMMENT "Running benchmarks"
    VERBATIM)

  # Run a single benchmark file:
  #   make bench-single FILE=ScalarBench.m
  add_custom_target(
    bench-single
    COMMAND
      ${WolframLanguage_wolframscript_EXE} -script
      ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m $(FILE) | tee
      ${CMAKE_CURRENT_BINARY_DIR}/bench.log
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/benchmarks/Benchmark.m
    COMMENT "Running benchmark")
endif()