makesetup.nsi

; Script generated by the HM NIS Edit Script Wizard.
SetCompressor lzma

; HM NIS Edit Wizard helper defines
!define PRODUCT_NAME "ljArchive"
!define PRODUCT_VERSION "0.9.10"
!define PRODUCT_PUBLISHER "sharpden"
!define PRODUCT_WEB_SITE "https://github.com/sharpden/ljarchive"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\ljArchive.exe"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

; MUI 1.67 compatible ------
!include "MUI.nsh"

; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "WindowsForms/res/App.ico"
!define MUI_UNICON "WindowsForms/res/App.ico"

; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE "License.txt"
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!define MUI_FINISHPAGE_RUN "$INSTDIR\ljArchive.exe"
!define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\index.htm"
!insertmacro MUI_PAGE_FINISH

; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES

; Language files
!insertmacro MUI_LANGUAGE "English"

; MUI end ------

Name "${PRODUCT_NAME}"
OutFile "${PRODUCT_NAME}-${PRODUCT_VERSION}-setup.exe"
InstallDir "$PROGRAMFILES\ljArchive"
InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
ShowInstDetails show
ShowUnInstDetails show

Function .onInit
   Call IsDotNETInstalled
   Pop $0
   StrCmp $0 1 found.NETFramework
   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "This installer cannot detect the .NET Framework on your computer.  You can download it from Windows Update, or visit the ljArchive web site for a download link.  ljArchive will not work without the .NET framework - do you want to install ljArchive anyway?" IDYES +2
   Abort
found.NETFramework:
FunctionEnd

Section "MainSection" SEC01
  SetOutPath "$INSTDIR"
  SetOverwrite try
  File "bin\Release\CommandBar.dll"
  File "bin\Release\CookComputing.XmlRpcLocal.dll"
  File "bin\Release\EF.ljArchive.Common.dll"
  File "bin\Release\EF.ljArchive.Engine.dll"
  SetOutPath "$INSTDIR\fr-FR"
  File "bin\Release\fr-FR\ljArchive.resources.dll"
  SetOutPath "$INSTDIR"
  File "bin\Release\GenghisLocal.dll"
  File "bin\Release\ljArchive.exe"
  CreateDirectory "$SMPROGRAMS\ljArchive"
  CreateShortCut "$SMPROGRAMS\ljArchive\ljArchive.lnk" "$INSTDIR\ljArchive.exe"
  SetOverwrite ifnewer
  File "index.htm"
  CreateShortCut "$SMPROGRAMS\ljArchive\ljArchive Info.lnk" "$INSTDIR\index.htm"
SectionEnd

Section "Plugins" SEC02
  SetOutPath "$INSTDIR\plugins"
  SetOverwrite try
  File "bin\Release\plugins\EF.ljArchive.Plugins.Core.dll"
  File "bin\Release\plugins\EF.ljArchive.Plugins.WindowsForms.dll"
  File "bin\Release\plugins\EF.ljArchive.XMLJournalWriter.dll"
  File "bin\Release\plugins\ZedGraph.dll"
SectionEnd

Section "Templates" SEC03
  SetOutPath "$INSTDIR\templates"
  File "etc\templates\component.ljt"
  File "etc\templates\generator.ljt"
  File "etc\templates\simple.ljt"
  File "etc\templates\talkread.ljt"
  File "etc\templates\unearthed.ljt"
SectionEnd

;Section -AdditionalIcons
;  CreateShortCut "$SMPROGRAMS\ljArchive\Uninstall.lnk" "$INSTDIR\uninst.exe"
;SectionEnd

Section -Post
  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\ljArchive.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\ljArchive.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
  
; back up old value of .lja
!define Index "Line${__LINE__}"
  ReadRegStr $1 HKCR ".lja" ""
  StrCmp $1 "" "${Index}-NoBackup"
    StrCmp $1 "ljArchive.Archive" "${Index}-NoBackup"
    WriteRegStr HKCR ".lja" "backup_val" $1
"${Index}-NoBackup:"
  WriteRegStr HKCR ".lja" "" "ljArchive.Archive"
  ReadRegStr $0 HKCR "ljArchive.Archive" ""
  StrCmp $0 "" 0 "${Index}-Skip"
	WriteRegStr HKCR "ljArchive.Archive" "" "ljArchive File"
	WriteRegStr HKCR "ljArchive.Archive\shell" "" "open"
	WriteRegStr HKCR "ljArchive.Archive\DefaultIcon" "" "$INSTDIR\ljArchive.exe,0"
"${Index}-Skip:"
;  WriteRegStr HKCR "ljArchive.Archive\shell\open" "" "Open ljArchive File"
  WriteRegStr HKCR "ljArchive.Archive\shell\open\command" "" \
    '$INSTDIR\ljArchive.exe "%1"'
!undef Index
  ; Rest of script
SectionEnd


Function un.onUninstSuccess
  HideWindow
  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer."
FunctionEnd

Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
  Abort
FunctionEnd

Section Uninstall
  ; Should remove everything previous installer could create
  Delete "$INSTDIR\uninst.exe"
  Delete "$INSTDIR\templates\unearthed.ljt"
  Delete "$INSTDIR\templates\talkread.ljt"
  Delete "$INSTDIR\templates\simple.ljt"
  Delete "$INSTDIR\templates\generator.ljt"
  Delete "$INSTDIR\templates\component.ljt"
  Delete "$INSTDIR\plugins\ZedGraph.dll"
  Delete "$INSTDIR\plugins\Interop.AgentObjects.dll"
  Delete "$INSTDIR\plugins\EF.SimpleMIDI.dll"
  Delete "$INSTDIR\plugins\EF.ljArchive.XMLJournalWriter.dll"
  Delete "$INSTDIR\plugins\EF.ljArchive.Plugins.WindowsForms.dll"
  Delete "$INSTDIR\plugins\EF.ljArchive.Plugins.Core.dll"
  Delete "$INSTDIR\plugins\EF.ljArchive.MIDIJournalWriter.dll"
  Delete "$INSTDIR\plugins\AxInterop.AgentObjects.dll"
  Delete "$INSTDIR\index.htm"
  Delete "$INSTDIR\Update.exe"
  Delete "$INSTDIR\ljArchive.exe"
  Delete "$INSTDIR\ICSharpCode.SharpZipLib.dll"
  Delete "$INSTDIR\GenghisLocal.dll"
  Delete "$INSTDIR\fr-FR\ljArchive.resources.dll"
  Delete "$INSTDIR\EF.ljArchive.Engine.dll"
  Delete "$INSTDIR\EF.ljArchive.Common.dll"
  Delete "$INSTDIR\CookComputing.XmlRpcLocal.dll"
  Delete "$INSTDIR\CommandBar.dll"

  Delete "$SMPROGRAMS\ljArchive\Uninstall.lnk"
  Delete "$SMPROGRAMS\ljArchive\ljArchive Info.lnk"
  Delete "$SMPROGRAMS\ljArchive\ljArchive.lnk"

  RMDir "$SMPROGRAMS\ljArchive"
  RMDir "$INSTDIR\templates"
  RMDir "$INSTDIR\plugins"
  RMDir "$INSTDIR\fr-FR"
  RMDir "$INSTDIR"

  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"

  ;start of restore script
!define Index "Line${__LINE__}"
  ReadRegStr $1 HKCR ".lja" ""
  StrCmp $1 "ljArchive.Archive" 0 "${Index}-NoOwn" ; only do this if we own it
    ReadRegStr $1 HKCR ".lja" "backup_val"
    StrCmp $1 "" 0 "${Index}-Restore" ; if backup="" then delete the whole key
      DeleteRegKey HKCR ".lja"
    Goto "${Index}-NoOwn"
"${Index}-Restore:"
      WriteRegStr HKCR ".lja" "" $1
      DeleteRegValue HKCR ".lja" "backup_val"

    DeleteRegKey HKCR "ljArchive.Archive" ;Delete key with association settings

"${Index}-NoOwn:"
!undef Index
  ;rest of script
  
  SetAutoClose true
SectionEnd

 ; IsDotNETInstalled
 ;
 ; Usage:
 ;   Call IsDotNETInstalled
 ;   Pop $0
 ;   StrCmp $0 1 found.NETFramework no.NETFramework

 Function IsDotNETInstalled
   Push $0
   Push $1
   Push $2
   Push $3
   Push $4

   ReadRegStr $4 HKEY_LOCAL_MACHINE \
     "Software\Microsoft\.NETFramework" "InstallRoot"
   # remove trailing back slash
   Push $4
   Exch $EXEDIR
   Exch $EXEDIR
   Pop $4
   # if the root directory doesn't exist .NET is not installed
   IfFileExists $4 0 noDotNET

   StrCpy $0 0

   EnumStart:

     EnumRegKey $2 HKEY_LOCAL_MACHINE \
       "Software\Microsoft\.NETFramework\Policy"  $0
     IntOp $0 $0 + 1
     StrCmp $2 "" noDotNET

     StrCpy $1 0

     EnumPolicy:

       EnumRegValue $3 HKEY_LOCAL_MACHINE \
         "Software\Microsoft\.NETFramework\Policy\$2" $1
       IntOp $1 $1 + 1
        StrCmp $3 "" EnumStart
         IfFileExists "$4\$2.$3" foundDotNET EnumPolicy

   noDotNET:
     StrCpy $0 0
     Goto done

   foundDotNET:
     StrCpy $0 1

   done:
     Pop $4
     Pop $3
     Pop $2
     Pop $1
     Exch $0
 FunctionEnd