flake.nix

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    fenix.url = "github:nix-community/fenix/monthly";
    crane.url = "github:ipetkov/crane";
  };

  outputs = { self, crane, flake-utils, fenix, nixpkgs }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = (import (nixpkgs) { inherit system; });
        deps = with pkgs; [
          openssl
          udev
          alsa-lib
          vulkan-loader
          clang
          lld
          xorg.libX11
          xorg.libXcursor
          xorg.libXi
          xorg.libXrandr
          libxkbcommon
          wayland
        ];
      in
      rec {
        packages.wasm =
          let
            pkgs = nixpkgs.legacyPackages.${system};
            craneLib = (crane.mkLib pkgs).overrideToolchain (with fenix.packages.${system};
              combine [
                minimal.cargo
                minimal.rustc
                targets.wasm32-unknown-unknown.latest.rust-std
              ]);

          in
          craneLib.buildPackage rec {
            src = ./.;
            doCheck = false;
            buildInputs = with pkgs; [ clang wasm-bindgen-cli ];
            CARGO_BUILD_TARGET = "wasm32-unknown-unknown";
            BEVY_ASSET_PATH = "${src}/assets";
            postInstall = "wasm-bindgen --no-typescript --target web --out-dir $out/wasm/ --out-name \"bevy-template\" $out/bin/bevy-template.wasm";
          };

        devShell =
          let
            toolchain = fenix.packages.${system}.latest.toolchain;
          in
          pkgs.mkShell rec {
            nativeBuildInputs = [ pkgs.pkg-config ];
            buildInputs =
              [
                toolchain
              ] ++ deps;
            LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildInputs;

            shellHook = ''
              echo "[🦀 Rust] environment is ready"
              rustc --version
            '';
          };

      });
}