Minasp/minasp.nix at main · tabe/Minasp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{ stdenv
, lib
, fetchFromGitHub
, emacs
, emacsPackages
, Mew-rev ? "v6.10"
, Mew-hash ? "sha256-p1QcnHoXdI4N7ewc5PQdq909wfKKiVFwdAyK6UPJUo0="
}: let

  mew-source = fetchFromGitHub {
    owner = "kazu-yamamoto";
    repo = "Mew";
    rev = Mew-rev;
    hash = Mew-hash;
  };

  mew-meta = with lib; {
    description = "Mew: Messaging in the Emacs World";
    homepage = "https://www.mew.org/";
    license = licenses.bsd3;
    inherit (emacs.meta) platforms;
  };

  minasp-version = "0.6.10";

  minasp-elisp = emacsPackages.trivialBuild {
    pname = "minasp-elisp";
    version = "${minasp-version}-${Mew-rev}";

    src = mew-source;

    buildFlags = [ "elisp" ];

    # Modified nixpkgs's pkgs/build-support/emacs/trivial.nix
    installPhase = ''
      runHook preInstall

      LISPDIR=$out/share/emacs/site-lisp/mew
      install -d $LISPDIR
      install elisp/*.el elisp/*.elc $LISPDIR
      emacs --batch -l package --eval "(package-generate-autoloads \"mew\" \"$LISPDIR\")"
      cp -r etc $LISPDIR/

      runHook postInstall
    '';

    meta = mew-meta;
  };

  minasp-utils = stdenv.mkDerivation {
    pname = "minasp-utils";
    version = "${minasp-version}-${Mew-rev}";

    src = mew-source;

    configureFlags = [ "--without-emacs" ];

    buildFlags = [ "bin" ];

    installTargets = [ "install-bin" ];

    meta = mew-meta;
  };

in {
  elisp = minasp-elisp;
  utils = minasp-utils;
}