nix-config/flake.nix at main · terlar/nix-config · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
{
  description = "Nix Config of Terje";

  nixConfig = {
    extra-substituters = "https://terlar.cachix.org https://cuda-maintainers.cachix.org";
    extra-trusted-public-keys = "terlar.cachix.org-1:M8CXTOaJib7CP/jEfpNJAyrgW4qECnOUI02q7cnmh8U= cuda-maintainers.cachix.org-1:0dq3bujKpuEPMCX6U4WylrUDZ9JyUG0VpVZa7CNfq5E=";
  };

  inputs = {
    flake-parts.url = "flake-parts";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable-small";
    home-manager = {
      url = "home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    emacs-config = {
      url = "github:terlar/emacs-config";
      inputs.flake-parts.follows = "flake-parts";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Modules
    nixos-hardware.url = "nixos-hardware";
    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{
      self,
      flake-parts,
      nixpkgs,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [ "x86_64-linux" ];

      imports = [
        flake-parts.flakeModules.partitions
        inputs.home-manager.flakeModules.default

        ./configurations/home/terje
        ./configurations/nixos/kong
        ./configurations/nixos/installer-yubikey
      ];

      partitionedAttrs = {
        checks = "dev";
        devShells = "dev";
        formatter = "dev";
      };

      partitions.dev = {
        extraInputsFlake = ./dev;
        module.imports = [ ./dev/flake-module.nix ];
      };

      flake = {
        lib = import ./lib.nix { inherit (nixpkgs) lib; };

        homeModules = nixpkgs.lib.mkMerge [
          (self.lib.modulesFromDir ./modules/home)
          {
            user-terje =
              { pkgs, ... }:
              {
                imports = [
                  self.homeModules.default
                  inputs.emacs-config.homeManagerModules.emacsConfig
                ];

                profiles.user.terje.enable = true;
                programs.home-manager.enable = true;

                custom.emacsConfig = {
                  package =
                    nixpkgs.lib.mkDefault
                      inputs.emacs-config.packages.${pkgs.stdenv.hostPlatform.system}.emacs-env-pgtk;
                  configPackage =
                    nixpkgs.lib.mkDefault
                      inputs.emacs-config.packages.${pkgs.stdenv.hostPlatform.system}.emacs-config-pgtk;
                };
              };

            user-terje-linux = {
              imports = [ self.homeModules.user-terje ];

              targets.genericLinux.enable = true;
            };
          }
        ];

        nixosModules = self.lib.modulesFromDir ./modules/nixos;

        overlays = {
          default = import ./packages;
        };
      };

      perSystem =
        { pkgs, ... }:
        {
          packages = {
            drduh-gpg-conf = pkgs.callPackage ./packages/drduh-gpg-conf { };
            drduh-yubikey-guide = pkgs.callPackage ./packages/drduh-yubikey-guide { };
          };
        };
    };
}