uzu/flake.nix at main · trymirai/uzu · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
{
  description = "A high-performance inference engine for AI models";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane.url = "github:ipetkov/crane";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs = {
    nixpkgs,
    rust-overlay,
    crane,
    flake-utils,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        overlays = [(import rust-overlay)];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
        lib = pkgs.lib;
        rustToolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;

        nativeBuildInputs = with pkgs;
          [
            # for xgrammar-rs
            cmake
          ]
          ++ (lib.optionals pkgs.stdenv.isDarwin [
            # impure hack to get metal toolchain
            (lib.hiPrio (writeShellScriptBin "xcrun" ''
              unset DEVELOPER_DIR
              exec /usr/bin/xcrun "$@"
            ''))
          ]);

        mirai = craneLib.buildPackage {
          pname = "mirai";
          src = ./.;

          cargoExtraArgs = "-p cli";
          installPhaseCommand = ''
            mkdir -p $out/bin
            install -Dm755 target/release/cli $out/bin/mirai
          '';

          inherit nativeBuildInputs;

          doCheck = false;
        };
      in {
        formatter = pkgs.alejandra;

        packages = {
          inherit mirai;
          default = mirai;
        };

        devShells.default = pkgs.mkShell ({
            nativeBuildInputs =
              nativeBuildInputs
              ++ (with pkgs; [
                nixd
                uv
                wasmtime
                evcxr
                rustToolchain
                cargo-deny
                cargo-nextest
                cargo-expand
                cargo-flamegraph
                cargo-show-asm
                critcmp
              ])
              ++ (lib.optionals pkgs.stdenv.isLinux (with pkgs; [
                pkg-config
                openssl
                alsa-lib
                clang
              ]));
          }
          // (lib.optionalAttrs pkgs.stdenv.isLinux {
            LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";
          }));
      }
    );
}