add toppra & hpp-toppra

Author: nim65s

flake.nix

@@ -310,6 +310,7 @@
                   hpp-statistics
                   hpp-template-corba
                   hpp-tools
+                  hpp-toppra
                   hpp-tutorial
                   hpp-universal-robot
                   hpp-util
@@ -321,6 +322,7 @@
                   odri-masterboard-sdk
                   pinocchio
                   proxsuite
+                  toppra
                   tsid
                   # keep-sorted end
                   ;
@@ -355,6 +357,7 @@
                   hpp-practicals
                   hpp-python
                   hpp-romeo
+                  hpp-toppra
                   hpp-tutorial
                   hpp-universal-robot
                   mim-solvers
@@ -365,6 +368,7 @@
                   proxsuite
                   sensitivity
                   toolbox-parallel-robots
+                  toppra
                   tsid
                   # keep-sorted end
                   ;

pkgs/hpp-toppra.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+
+  # nativeBuildInputs
+  cmake,
+  pkg-config,
+  hpp-core,
+  hpp-manipulation,
+
+  # buildInputs
+  jrl-cmakemodules,
+  python3Packages,
+  toppra,
+}:
+
+stdenv.mkDerivation (_finalAttrs: {
+  pname = "hpp-toppra";
+  version = "0-unstable-2026-03-19";
+
+  src = fetchFromGitHub {
+    owner = "humanoid-path-planner";
+    repo = "hpp-toppra";
+    rev = "cdf624daede95f17d7f1cdec58435b712b4e3d21";
+    hash = "sha256-f+bc0pLNiAcOObarHuiGZHFs0jbmbS82od1f1eKS6f4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    jrl-cmakemodules
+    hpp-core
+    hpp-manipulation
+    python3Packages.boost
+    python3Packages.eigenpy
+    python3Packages.numpy
+    python3Packages.hpp-python
+    toppra
+  ];
+
+  meta = {
+    description = "Integration of TOPPRA algorithm in HPP";
+    homepage = "https://github.com/humanoid-path-planner/hpp-toppra";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/toppra.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+
+  # nativeBuildInputs
+  cmake,
+  python3Packages,
+
+  # buildInputs
+  eigen,
+  glpk,
+  msgpack-cxx,
+  pinocchio,
+  qpoases,
+
+  # checkInputs
+  gtest,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "toppra";
+  version = "0.6.7";
+
+  src = fetchFromGitHub {
+    owner = "hungpham2511";
+    repo = "toppra";
+    tag = finalAttrs.version;
+    hash = "sha256-37FHQmcAlSiavaJdJrsWfMaxU7I06f+MNQA8hvtQ0mw=";
+  };
+
+  sourceRoot = "source/cpp";
+
+  # fix ld: cannot open output file
+  # /build/source/toppra/toppra/cpp/toppra_int.cpython-313-x86_64-linux-gnu.so:
+  # No such file or directory
+  postPatch = ''
+    substituteInPlace bindings/CMakeLists.txt --replace-fail \
+      "LIBRARY_OUTPUT_DIRECTORY $""{TOPPRA_PYTHON_SOURCE_DIR}" \
+      "LIBRARY_OUTPUT_DIRECTORY $""{CMAKE_CURRENT_BINARY_DIR}"
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    python3Packages.pybind11
+  ];
+
+  buildInputs = [
+    python3Packages.boost
+    eigen
+    glpk
+    msgpack-cxx
+    pinocchio
+    # python3Packages.pinocchio
+    qpoases
+  ];
+
+  checkInputs = [
+    gtest
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTS" finalAttrs.doCheck)
+    (lib.cmakeBool "BUILD_WITH_PINOCCHIO" true)
+    (lib.cmakeBool "BUILD_WITH_PINOCCHIO_PYTHON" true)
+    (lib.cmakeBool "BUILD_WITH_qpOASES" true)
+    (lib.cmakeBool "BUILD_WITH_GLPK" true)
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+    (lib.cmakeBool "OPT_MSGPACK" true)
+    (lib.cmakeBool "PYTHON_BINDINGS" true)
+    (lib.cmakeFeature "PYTHON_VERSION" (lib.versions.majorMinor python3Packages.python.version))
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Robotic motion planning library";
+    homepage = "https://github.com/hungpham2511/toppra";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.all;
+  };
+})

py-pkgs/hpp-toppra.nix

@@ -0,0 +1,9 @@
+{
+  toPythonModule,
+  pkgs,
+}:
+toPythonModule (
+  pkgs.hpp-toppra.override {
+    inherit (pkgs) python3Packages;
+  }
+)

py-pkgs/toppra.nix

@@ -0,0 +1,9 @@
+{
+  toPythonModule,
+  pkgs,
+}:
+toPythonModule (
+  pkgs.toppra.override {
+    inherit (pkgs) python3Packages;
+  }
+)