feat: Add nix files

.envrc

@@ -0,0 +1 @@
+use nix

.gitignore

@@ -47,3 +47,5 @@ next-env.d.ts
 
 # virtual env for gitlint
 /env-gitlint
+.direnv
+result

default.nix

@@ -0,0 +1,21 @@
+{
+  sources ? import ./npins,
+  pkgs ? import sources.nixpkgs { },
+}:
+
+let
+  inherit (pkgs.lib.filesets) toSource unions;
+in
+
+{
+  devShell = pkgs.mkShell {
+    name = "hackdays.dev";
+
+    packages = with pkgs; [
+      nodejs
+      yarn
+    ];
+  };
+
+  package = pkgs.callPackage ./package.nix { };
+}

npins/default.nix

@@ -0,0 +1,80 @@
+# Generated by npins. Do not modify; will be overwritten regularly
+let
+  data = builtins.fromJSON (builtins.readFile ./sources.json);
+  version = data.version;
+
+  mkSource =
+    spec:
+    assert spec ? type;
+    let
+      path =
+        if spec.type == "Git" then
+          mkGitSource spec
+        else if spec.type == "GitRelease" then
+          mkGitSource spec
+        else if spec.type == "PyPi" then
+          mkPyPiSource spec
+        else if spec.type == "Channel" then
+          mkChannelSource spec
+        else
+          builtins.throw "Unknown source type ${spec.type}";
+    in
+    spec // { outPath = path; };
+
+  mkGitSource =
+    {
+      repository,
+      revision,
+      url ? null,
+      hash,
+      branch ? null,
+      ...
+    }:
+    assert repository ? type;
+    # At the moment, either it is a plain git repository (which has an url), or it is a GitHub/GitLab repository
+    # In the latter case, there we will always be an url to the tarball
+    if url != null then
+      (builtins.fetchTarball {
+        inherit url;
+        sha256 = hash; # FIXME: check nix version & use SRI hashes
+      })
+    else
+      assert repository.type == "Git";
+      let
+        urlToName =
+          url: rev:
+          let
+            matched = builtins.match "^.*/([^/]*)(\\.git)?$" repository.url;
+
+            short = builtins.substring 0 7 rev;
+
+            appendShort = if (builtins.match "[a-f0-9]*" rev) != null then "-${short}" else "";
+          in
+          "${if matched == null then "source" else builtins.head matched}${appendShort}";
+        name = urlToName repository.url revision;
+      in
+      builtins.fetchGit {
+        url = repository.url;
+        rev = revision;
+        inherit name;
+        # hash = hash;
+      };
+
+  mkPyPiSource =
+    { url, hash, ... }:
+    builtins.fetchurl {
+      inherit url;
+      sha256 = hash;
+    };
+
+  mkChannelSource =
+    { url, hash, ... }:
+    builtins.fetchTarball {
+      inherit url;
+      sha256 = hash;
+    };
+in
+if version == 3 then
+  builtins.mapAttrs (_: mkSource) data.pins
+else
+  throw "Unsupported format version ${toString version} in sources.json. Try running `npins upgrade`"

npins/sources.json

@@ -0,0 +1,11 @@
+{
+  "pins": {
+    "nixpkgs": {
+      "type": "Channel",
+      "name": "nixpkgs-unstable",
+      "url": "https://releases.nixos.org/nixpkgs/nixpkgs-25.05pre776565.63158b9cbb6e/nixexprs.tar.xz",
+      "hash": "0l91nfx2j2j279z4zsp2fm1rrl38lxiw2y94zkn82860xynfl9z1"
+    }
+  },
+  "version": 3
+}

package.nix

@@ -0,0 +1,71 @@
+{
+  stdenv,
+  lib,
+  fetchYarnDeps,
+  nodejs,
+  yarn,
+  fixup-yarn-lock,
+}:
+
+let
+  inherit (lib.fileset) toSource unions;
+in
+
+stdenv.mkDerivation {
+  pname = "hackdays";
+  version = "0.1";
+
+  offlineCache = fetchYarnDeps {
+    yarnLock = ./yarn.lock;
+    hash = "sha256-10b8l45zXYZRiNwvwuG8q/8IrupV3AEJxliwCpgkMeE=";
+  };
+
+  src = toSource {
+    root = ./.;
+
+    fileset = unions [
+      ./public
+      ./src
+      ./eslint.config.mjs
+      ./favicon.ico
+      ./next.config.ts
+      ./package.json
+      ./postcss.config.js
+      ./tailwind.config.ts
+      ./tsconfig.json
+      ./yarn.lock
+    ];
+  };
+
+  nativeBuildInputs = [
+    fixup-yarn-lock
+    nodejs
+    yarn
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    export HOME=$(pwd)
+
+    fixup-yarn-lock yarn.lock
+    yarn config --offline set yarn-offline-mirror $offlineCache
+    yarn install --offline --frozen-lockfile --no-progress --non-interactive
+
+    patchShebangs node_modules
+
+    runHook postConfigure
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    yarn build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    mv out $out
+  '';
+}

shell.nix

@@ -0,0 +1 @@
+(import ./. { }).devShell